ViSiToR
Silver Member | Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
stall
Цитата:| как сделать распаковку файлов без использования сторонних средств |
Код: Zip = "C:\Test.zip"
Dest = "C:\test"
UnZipFiles Zip, Dest
Function UnZipFiles(sZipFile, sDest)
'Create Shell.Application object
Set oShell = WScript.CreateObject("Shell.Application")
'Get zip file namespace object
Set oFolder = oShell.NameSpace(sZipFile)
'Get list of items in zip file
Set oItems = oFolder.Items
'If not exists, create destination folder
Set fso = CreateObject("Scripting.FileSystemObject")
If fso.FolderExists(sDest) = 0 Then fso.CreateFolder(sDest)
'Get destination folder namespace object
Set oDest = oShell.NameSpace(sDest & "\")
'Extract the files
oDest.CopyHere oItems, 64
End Function |
Странно что подобная функция для запаковки файлов не работает:
Код:
Zip = "C:\Test.zip"
Source = "C:\test"
ZipFiles Zip, Source
Function ZipFiles(sZipFile, sSource)
'If not exists, create the Zip file.
Set fso = CreateObject("Scripting.FileSystemObject")
If fso.FileExists(sZipFile) = 0 Then
Set oFile = fso.OpenTextFile(sZipFile, 2, True)
sHeader = Chr(80) & Chr(75) & Chr(5) & Chr(6)
For i = 1 To 18
sHeader = sHeader & Chr(0)
Next
oFile.Write sHeader
oFile.Close
End If
'Create Shell.Application Object
Set oShell = WScript.CreateObject("Shell.Application")
'Get zip file object
Set oFolder = oShell.NameSpace(sZipFile)
'Copy source file or folder to zip file
If fso.FolderExists(sSource) <> 0 Then
Set oNameSpace = oShell.NameSpace(sSource)
oFolder.CopyHere oNameSpace.Items, 64
Else
oFolder.CopyHere sSource, 64
End If
End Function |
Кто-нибудь знает в чём причина?
----------
ViSiToR a.k.a CreatoR
CreatoR это не ник, CreatoR это стиль жизни! |
|
