ViSiToR
Silver Member | Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
adSka 00:33 09-02-2009
Цитата:| можно ли с помощью скриптов vb или js создавать интерактивные формы (с чекбоксами, переключателями и тд..)? |
Нет (за исключением InputBox  ).
Цитата:| или может можно создавать их с помощью чего-то другого и передавать скрипту результаты? |
Можно с AutoIt.
Цитата:
Да нет вроде, COM в vbs ведь поддерживается
ponand 10:14 04-02-2009
Цитата:| как с помощью jscript или vbscript скрипта открыть страницу в IE перебрать все ссылки и нужные отправить в DM ? |
Вот так можно:
Код: 'Получаем объект для инстанции Internet Explorer
Set oIE = WScript.CreateObject("InternetExplorer.Application")
'Указываем переменную содержащую страницу для проверки
sURL = "www.google.ru"
'Задаём состояние окна IE (невидимое)
oIE.Visible = False
'Переходим по ссылке
oIE.Navigate(sURL)
'Ждём полной загрузкий страницы
While oIE.ReadyState <> 4 And StrComp(oIE.ReadyState, "complete") = -1
WScript.Sleep(10)
WEnd
'Получаем объект со всеми ссылками на странице
Set oLinks = oIE.Document.Links
'Получаем общее число ссылок
iTotal_Links = oIE.Document.Links.Length
'Переменная для списка ссылок (только для отображения)
sLinks = ""
'Проходимся по всем ссылкам помещая их в список
For Each oLink In oLinks
sLinks = sLinks & "[" & oLink.Href & "], [" & oLink.innerText & "]" & vbCRLF
Next
'Выводим список на экран, плюс спрашиваем о продолжении передачи в DM
iAskQuit = MsgBox("Pass theese links to DM?" & vbCRLF & vbCRLF & sLinks, 36, "Links (" & iTotal_Links & ") List")
'Если юзер отказался, выходим из скрипта
If iAskQuit <> 6 Then
oIE.Quit
Wscript.Quit
End If
'Подавление критических ошибок
On Error Resume Next
'Объявляем массив для хранения ссылок (нужно для DM)
ReDim aLinksArray(iTotal_Links*2)
'Счётчик для заполнения массива
i = 0
'Проходимся по всем ссылкам и помещаем их в массив
For Each oLink In oLinks
aLinksArray(i*2) = oLink.Href 'oLink.Href это адрес
aLinksArray(i*2+1) = oLink.innerText 'oLink.innerText это заголовок ссылки
'Увеличиваем счётчик при каждом цикле на единицу
i = i + 1
Next
'Получаем объект dmie.moveurl (для передаи данных в DM)
Set DMCOMObj = WScript.CreateObject("dmie.moveurl")
'Если ошибка, выводим сообщение
If Err <> 0 Then
MsgBox("ActiveX automation object placed in DMIE.DLL is not registered or corrupted. " & _
"Please try reinstall Download Master")
Else
'Передаём ссылки в DM
Call DMCOMObj.AddURLs(aLinksArray, sURL)
End If
'Закрываем инстанцию IE
oIE.Quit |
----------
ViSiToR a.k.a CreatoR
CreatoR это не ник, CreatoR это стиль жизни! |
|
Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 01:17 09-02-2009 | Исправлено: ViSiToR, 15:27 10-02-2009 |
|
