res2001
Silver Member | Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Magadan69
Что есть КСОР?
Дык вопрос в том как перевести из шестнадцатиричной системы в десятичную? Если да то так:
set "hex=fcbd"
set /a "dec=0x%hex%"
echo %dec%
Обратно сложнее, вот когда-то писал:
Код: @echo off
SetLocal EnableDelayedExpansion
::В параметре получает десятичное число, в переменной %NUM16% возвращает его шестнадцатиричный эквивалент.
set "NUM16="
set "dig=0123456789ABCDEF"
for /l %%x in (0,1,5) do (
call:degree 16 %%x
set /a "nn=%1/!degree!%%16"
call set "NUM16=%%dig:~!nn!,1%%!NUM16!"
)
::Убираем незначащие нули
:notnul
if "%NUM16:~,1%" equ "0" (set "NUM16=%NUM16:~1%" & goto:notnul)
echo.%NUM16%
endlocal
exit /b
::Возвращает в переменной degree степень %2 числа %1.
::Вычисляется только положительная степень числа.
:degree
if "%2" equ "0" set "degree=1" & exit /b
set "degree=%1"
for /l %%z in (2,1,%2) do set /a "degree*=%1"
exit /b
|
Добавлено:
ааа, понял ксор - это xor :-)
Батники поддерживают двоичные операции. xor.bat
Код: @echo off
set /a "val=%1^%2"
echo %val% |
В параметрах передаешь десятичные числа.
Для реализации шестнадцатиричных чисел читай выше.
|
Всего записей: 2580 | Зарегистр. 11-04-2003 | Отправлено: 18:09 15-12-2011 | Исправлено: res2001, 18:10 15-12-2011 |
|
elapp 
