Перейти из форума на сайт.


Система IP-видеонаблюдения "Линия". Скачать бесплатную демо-версию для 16 камер. НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаФотогалереяГазетаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » AutoIT (Часть 1)

Модерирует : gyra, Maz

Widok (12-01-2009 14:47): лимит страниц. продолжаем здесь  Версия для печати • ПодписатьсяДобавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138

Открыть новую тему    

AddXL

Newbie
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

AutoIt3

 
Домашняя страница: http://www.autoitscript.com
Страница загрузки: http://www.autoitscript.com/autoit3/downloads.php
 
Описание:

Цитата:
AutoIt v3 - это язык для написания сценариев, напоминающий BASIC. Основным его назначением является автоматизация работ с Windows GUI (графическим интерфейсом пользователя MS Windows). Для выполнения этой сложной задачи предоставляется комбинация испытанных методов, включающих в себя - симуляцию нажатий комбинаций клавиш клавиатуры, перемещения указателя мыши и управления окнами и его визуальными элементами. Как показывает практика, эти "приводные ремни" весьма эффективны для получения работающих решений в ситуациях, когда другие стандартные средства (например, VBScript и SendKeys) оказываются бессильны.
Умеет он очень и очень многое! Бесплатный.

 
Помощь по AutoIT:
  • Справку на русском (и не только) вы всегда(?) сможете найти тут
  • Справочник по командам rundll32
  • Русский справочник по API-функциям
  • Помощь по Регулярным выражениям
  • AutoIt v3: Your Quick Guide (652 КБ) - Ваш быстрый гид в мир AutoIt-а (книга в формате pdf)
     
    Инструметы для AutoIt:
  • AutoIt3Wrapper [Страница закачки] - Программа для компилляции скрипта с дополнительными возможностями (добавление иконки, описании и т.п).
  • Koda (724 Kb) - Визуализация работы с GUI - аналог Visual Basic.
  • CodeWizard (400 Kb) - нечто простенькое на вариант Koda.
  • AutoItMacroGenerator (34 Kb) - Записывает в реальном времени действия пользователя в AutoIt код.
  • ScriptWriter (78 Kb) - Аналог AutoItMacroGenerator.
  • API Constants (1042 Kb) - Утилита для просмотра всех констант API-Функции и не только.
  • Страница закачки утилит которые идут в отдельной поставке редактора SciTE.
  • AutoIt меню для браузера Opera
     
    Готовые скрипты и программы с открытым кодом на AutoIt:
  • Коллекция AutoIt скриптов от Sanja Alone
  • Коллекция скриптов на http://msfn.org
  • Пополняющийся со временем сайт с полезными утилитами и функциями на AutoIt
  • Desktop Icons Restorator - Скрипт-Программа для сохранения/восстановления позиции иконок р.стола.
  • CaptureIt - Утилита предназначена для захвата изображений с вашего экрана.
  • SwitchIt - Скрипт для конвертирования выделенного текста
  • Скрипт расскраски кода AutoIt для публикации в форумах
     
    Общие вопросы и решения на Autoit:
  • Обработчик скриптов добавляющий отладчик (debugger)
  • Интеракция между несколькими скриптами
  • Пример использование интеракции между скриптами - Добавление элементов GUI с внешнего модуля
  • Копирование большого файла с отображением данных прогресса
  • Создание динамического меню в Tray Icon (значёк в области уведомления)
  • Пример создания своего мастера (Wizard)
  • Метод позволяющий запускать код VBS не создавая временных файлов
  • Описание функции GUIRegisterMsg()
  • Пример перехвата вводимых символов с клавиатуры
  • Пример деактивирования TabItem
  • Пример вывода лога в Edit-поле (с поддержкой форматирования текста)
  • Пример остановки/начало выполнения скрипта + Слежение за б.обмена с заменой неподдерживаемых в имени файла символов
  • Пример использования меню с иконками (ModernMenu.au3) -> Список программ в меню значка в системном трее
     
  • Как по PID процесса вычислить путь запускаемого файла
  • Получение IP по подключенному сокету
     
    Отдельные функции (UDF):
  • Функции Отключения/Подключения к Интернету
  • Функция проверки подключения к Интернету
  • Функция для получения структуры директории включая подкаталоги
  • Функция для поиска в файлах
  • Функция для смены разрешения экрана
  • Функция для смены раскладки клавиатуры в определённом окне
  • Функция для получения списка процессов с допол. инфой (путь к исполняемому файлу и др.)
  • Функции и пример для отображения детального процесса закачки файла
  • Функция (и пример использования) для отображения стильного диалога “О Программе” - [Усовершенствованная версия]
  • Функция возвращает пронумерованный список всех классов определённого окна + функция получения хендлов для этих классов
  • Функция для получения заголовка окна (или его идентификатора) по ID процесса (PID)
  • Функция _StringIsUTF8Format() + _StringToUTF() - Первая проверяет если строка содержится в UTF-8 формате, вторая преобразовывает строку в UTF-8 формат
  • Функция _FileOpenDialogEx - Возвращает массив (или строку) с полными путями к выбранным файлам
  • _AU3_Lib* Функции - Предназначены для обработки подключаемых библиотек через #include
  • Функция транслитерации строки
  • Расширенная библиотека для работы с реестром
     
    За шапкой следит ViSiToR  

  • Всего записей: 6 | Зарегистр. 24-11-2005 | Отправлено: 13:20 24-11-2005 | Исправлено: Maz, 11:50 17-04-2017
    Tipulatoid



    Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    ViSiToR
    Спасибо большое. А можно доделать тот пример? Требуется, если хотя бы одна из иконок $Icon2_3_1 $Icon2_4_1 $Icon2_5_1 $Icon2_6_1 имеет статус $GUI_SHOW кнопка Далее стала бы недоступна (в противном случае - доступна). Куда только не сую в код эти проверки - всё не то получается.

    Всего записей: 349 | Зарегистр. 22-12-2006 | Отправлено: 10:07 13-09-2008 | Исправлено: Tipulatoid, 11:24 13-09-2008
    ViSiToR



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    Tipulatoid 10:07 13-09-2008
    Цитата:
    можно доделать тот пример?

    Да. Также немного изменил принцип проверки, теперь при изменении в любом из инпутов, будут проверяться все остальные, это чтобы сократить количество проверок, а также это облегчает задать статус кнопке «Далее».
     

    Код:
    #include <GuiConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <StaticConstants.au3>
    #include <EditConstants.au3>
     
    ; Устанавливаем иконки
    ;Используются системные
    ;FileInstall("Resources\Ok.ico", "Ok.ico")
    ;FileInstall("Resources\NotOk.ico", "NotOk.ico")
     
    ;Рисуем главное окно

    $Main_GUI = GUICreate("Мастер создания настроек", 500, 360, (@DesktopWidth - 500) / 2, (@DesktopHeight - 300) / 2)
    _GUICtrlCreateSeperator(0, 2, 320, 3, 496)
    ; Рисуем кнопки
    $Back_Button = GUICtrlCreateButton("< Назад", 240, 327, 80)
    GUICtrlSetState(-1, $GUI_DISABLE)
    $Next_Button = GUICtrlCreateButton("Далее >", 320, 327, 80)
    $Exit_Button = GUICtrlCreateButton("Выход", 410, 327, 80)
     
    ;Рисуем первый диалог мастера
    $ChildGui_1 = GUICreate("", 493, 300, 1, 1, $WS_POPUP)
    DllCall("user32.dll", "int", "SetParent", "hwnd", $ChildGui_1, "hwnd", $Main_GUI) ; помещаем диалог в главное окно
    $Label1_1_1 = GUICtrlCreateLabel("Этот мастер создания настроек последовательно проведет Вас через все шаги создания нового Интернет-чемпионата по деловой игре ""Никсдорф-Дельта"".", 30, 50, 450, 34)
    $Label1_1_2 = GUICtrlCreateLabel("Вы всегда можете вызвать справку в любом диалоге, нажав F1", 30, 84, 450, 17)
     
    ;Рисуем второй диалог мастера
    $ChildGui_2 = GUICreate("", 493, 300, 1, 1, $WS_POPUP)
    DllCall("user32.dll", "int", "SetParent", "hwnd", $ChildGui_2, "hwnd", $Main_GUI) ; помещаем диалог в главное окно
    $Label2_1_1 = GUICtrlCreateLabel("Шаг 1/10: Общие настройки", 24, 8, 147, 17)
    $Group2_2_1 = GUICtrlCreateGroup("Приветствие", 32, 32, 455, 41)
    $Checkbox2_2_1 = GUICtrlCreateCheckbox("Выводить приветствие AutoSend&&Get при запуске", 48, 48, 273, 17, $WS_TABSTOP)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    $Group2_3_1 = GUICtrlCreateGroup("Название чемпионата", 32, 80, 455, 41)
    $Label2_3_1 = GUICtrlCreateLabel("Введите название чемпионата:", 48, 100, 163, 17)
    $Input2_3_1 = GUICtrlCreateInput("Грейт-4", 210, 96, 113, 21, $WS_TABSTOP)
    $Icon_2_3_1 = GUICtrlCreateIcon("inetcpl.cpl", -23, 435, 98, 15, 15)
    $Icon_2_3_2 = GUICtrlCreateIcon("inetcpl.cpl", -22, 450, 90, 25, 25)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    $Group2_4_1 = GUICtrlCreateGroup("E-mail", 32, 128, 455, 68)
    $Label2_4_1 = GUICtrlCreateLabel("Введите адрес основного ящика, через который Вы будете общаться с участниками. Внимание! Именно ящик для живого общения, а не для рассылки архивов.", 48, 140, 436, 27)
    $Input2_4_1 = GUICtrlCreateInput("delta-greit@yandex.ru", 280, 170, 150, 21, $WS_TABSTOP)
    $Icon_2_4_1 = GUICtrlCreateIcon("inetcpl.cpl", -23, 435, 173, 15, 15)
    $Icon_2_4_2 = GUICtrlCreateIcon("inetcpl.cpl", -22, 450, 165, 25, 25)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    $Group2_5_1 = GUICtrlCreateGroup("Форум", 32, 200, 455, 53)
    $Label2_5_1 = GUICtrlCreateLabel("Введите номер топика Вашего турнира на форуме:", 48, 215, 260, 17)
    $Label2_5_2 = GUICtrlCreateLabel("http://deltaon.ucoz.ru/forum/2-", 49, 230, 149, 17)
    $Input2_5_1 = GUICtrlCreateInput("20", 200, 227, 25, 21, $WS_TABSTOP)
    $Icon_2_5_1 = GUICtrlCreateIcon("inetcpl.cpl", -23, 435, 228, 15, 15)
    $Icon_2_5_2 = GUICtrlCreateIcon("inetcpl.cpl", -22, 450, 220, 25, 25)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    $Group2_6_1 = GUICtrlCreateGroup("Периоды", 32, 257, 455, 41)
    $Label2_6_1 = GUICtrlCreateLabel("Введите количество периодов (от 1 до 20):", 48, 275, 220, 17)
    $InputGui_2_6_1 = GUICtrlCreateInput("12", 265, 273, 34, 17)
    $UpDownGui_2_6_1 = GUICtrlCreateUpdown($InputGui_2_6_1)
    GUICtrlSetLimit(-1, 20, 1)
    $Icon_2_6_1 = GUICtrlCreateIcon("inetcpl.cpl", -23, 435, 275, 15, 15)
    $Icon_2_6_2 = GUICtrlCreateIcon("inetcpl.cpl", -22, 450, 267, 25, 25)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
     
    ;Рисуем третий диалог мастера
    $ChildGui_3 = GUICreate("", 493, 300, 1, 1, $WS_POPUP)
    DllCall("user32.dll", "int", "SetParent", "hwnd", $ChildGui_3, "hwnd", $Main_GUI) ; помещаем диалог в главное окно
    $Label3_1_1 = GUICtrlCreateLabel("Шаг 2/10: Настройка исходящих писем", 24, 8, 200, 17)
     
    $Group3_2_1 = GUICtrlCreateGroup("Создание текстов писем", 32, 32, 455, 120)
    $Checkbox3_2_1 = GUICtrlCreateCheckbox("Использовать шаблоны", 48, 50, 140, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Button3_2_1 = GUICtrlCreateButton("Пример", 320, 48, 60, 20)
    $Checkbox3_2_2 = GUICtrlCreateCheckbox("Использовать обычный шаблон", 62, 75, 180, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Button3_2_2 = GUICtrlCreateButton("Указать", 320, 73, 60, 20)
    ;GUICtrlSetState (-1, $GUI_DISABLE)
    $Button3_2_5 = GUICtrlCreateButton("Редактировать", 390, 73, 90, 20)
    $Checkbox3_2_3 = GUICtrlCreateCheckbox("Использовать шаблон выходного дня", 62, 100, 210, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Button3_2_3 = GUICtrlCreateButton("Указать", 320, 98, 60, 20)
    $Button3_2_6 = GUICtrlCreateButton("Редактировать", 390, 98, 90, 20)
    $Checkbox3_2_4 = GUICtrlCreateCheckbox("Использовать шаблон последнего периода", 62, 125, 240, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Button3_2_4 = GUICtrlCreateButton("Указать", 320, 123, 60, 20)
    $Button3_2_7 = GUICtrlCreateButton("Редактировать", 390, 123, 90, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
     
    $Group3_3_1 = GUICtrlCreateGroup("Тексты писем и архивы", 32, 217, 455, 78)
    $Checkbox3_3_1 = GUICtrlCreateCheckbox("Сохранять отправленные", 48, 233, 145, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Button3_3_1 = GUICtrlCreateButton("Выбрать папку", 200, 230, 85, 25, 0)
    $Label3_3_1 = GUICtrlCreateLabel("Текущая папка: ", 48, 250, 90, 17)
    If Not IsDeclared("save_path") Then $save_path = @ScriptDir & "\to_send"
    $Label3_3_2 = GUICtrlCreateLabel($save_path, 48, 265, 435, 25)
    GUICtrlSetColor(-1, 0x335EA8)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
     
    _CheckInputsProc()
     
    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
     
    ;Выводим окна на экран
    GUISetState(@SW_SHOW, $Main_GUI)
    GUISetState(@SW_SHOW, $ChildGui_1)
    GUISetState(@SW_HIDE, $ChildGui_2)
    GUISetState(@SW_HIDE, $ChildGui_3)
     
    While 1
        $Msg = GUIGetMsg(1)
     
        Switch $Msg[0]
            Case $GUI_EVENT_CLOSE, $Exit_Button
                If Not _WinIsVisible($ChildGui_1) Then
                    $Ask = MsgBox(4096+36, "Attention", "Are you sure you want to exit the Wizard now?", 0, $Msg[1])
                    If $Ask <> 6 Then ContinueLoop
                EndIf
     
                If
    $Msg[1] = $Main_GUI Then Exit
            Case
    $Next_Button
                GUICtrlSetState($Back_Button, $GUI_ENABLE)
     
                Local $CurrentHandle = 0
                Local $NextHandle = 0
     
                Select
                    Case
    _WinIsVisible($ChildGui_1)
                        $CurrentHandle = $ChildGui_1
                        $NextHandle = $ChildGui_2
                        _CheckInputsProc(1)
                    Case _WinIsVisible($ChildGui_2)
                        $CurrentHandle = $ChildGui_2
                        $NextHandle = $ChildGui_3
                        GUICtrlSetState($Next_Button, $GUI_DISABLE)
                EndSelect
     
                If $CurrentHandle <> 0 Then
                    GUISetState(@SW_HIDE, $CurrentHandle)
                    GUISetState(@SW_SHOW, $NextHandle)
                EndIf
     
                WinActivate($Main_GUI)
            Case $Back_Button
                GUICtrlSetState($Next_Button, $GUI_ENABLE)
     
                Local $CurrentHandle = 0
                Local $BackHandle = 0
     
                Select
                    Case _WinIsVisible($ChildGui_3)
                        $CurrentHandle = $ChildGui_3
                        $BackHandle = $ChildGui_2
                    Case _WinIsVisible($ChildGui_2)
                        $CurrentHandle = $ChildGui_2
                        $BackHandle = $ChildGui_1
                        GUICtrlSetState($Back_Button, $GUI_DISABLE)
                EndSelect
     
                If $CurrentHandle <> 0 Then
                    GUISetState(@SW_HIDE, $CurrentHandle)
                    GUISetState(@SW_SHOW, $BackHandle)
                EndIf
     
                WinActivate($Main_GUI)
        EndSwitch
    WEnd
     
    Func _GUICtrlCreateSeperator($Direction, $Left, $Top, $Width = 3, $Lenght = 25)
        Switch $Direction
            Case 0
                GUICtrlCreateLabel("", $Left, $Top, $Lenght, $Width, $SS_SUNKEN)
            Case 1
                GUICtrlCreateLabel("", $Left, $Top, $Width, $Lenght, $SS_SUNKEN)
        EndSwitch
    EndFunc   ;==>_GUICtrlCreateSeperator
     
    Func _WinIsVisible($hWnd)
        Return BitAND(WinGetState($hWnd), 2)
    EndFunc   ;==>_WinIsVisible
     
    Func _CheckInputsProc($iCheckNextButton=0)
        Local $iNextButtonState = $GUI_ENABLE
     
        If GUICtrlRead($Input2_3_1) = "" Then
            _GUICtrlSetState($Icon_2_3_1, $GUI_SHOW)
            _GUICtrlSetState($Icon_2_3_2, $GUI_HIDE)
     
            $iNextButtonState = $GUI_DISABLE
        Else
            _GUICtrlSetState($Icon_2_3_1, $GUI_HIDE)
            _GUICtrlSetState($Icon_2_3_2, $GUI_SHOW)
        EndIf
     
        If GUICtrlRead($Input2_4_1) = "" Then
            _GUICtrlSetState($Icon_2_4_1, $GUI_SHOW)
            _GUICtrlSetState($Icon_2_4_2, $GUI_HIDE)
     
            $iNextButtonState = $GUI_DISABLE
        Else
            _GUICtrlSetState($Icon_2_4_1, $GUI_HIDE)
            _GUICtrlSetState($Icon_2_4_2, $GUI_SHOW)
        EndIf
     
        If GUICtrlRead($Input2_5_1) = "" Then
            _GUICtrlSetState($Icon_2_5_1, $GUI_SHOW)
            _GUICtrlSetState($Icon_2_5_2, $GUI_HIDE)
     
            $iNextButtonState = $GUI_DISABLE
        Else
            _GUICtrlSetState($Icon_2_5_1, $GUI_HIDE)
            _GUICtrlSetState($Icon_2_5_2, $GUI_SHOW)
        EndIf
     
        If GUICtrlRead($InputGui_2_6_1) <> 12 Then
            _GUICtrlSetState($Icon_2_6_1, $GUI_SHOW)
            _GUICtrlSetState($Icon_2_6_2, $GUI_HIDE)
     
            $iNextButtonState = $GUI_DISABLE
        Else
            _GUICtrlSetState($Icon_2_6_1, $GUI_HIDE)
            _GUICtrlSetState($Icon_2_6_2, $GUI_SHOW)
        EndIf
     
        If $iCheckNextButton Then _GUICtrlSetState($Next_Button, $iNextButtonState)
    EndFunc   ;==>_CheckInputsProc
     
    Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
        Local $nNotifyCode = BitShift($wParam, 16)
        Local $nID = BitAND($wParam, 0xFFFF)
        Local $hCtrl = $lParam
     
        Switch $nNotifyCode
            Case $EN_CHANGE, $EN_UPDATE
                _CheckInputsProc(1)
        EndSwitch
     
        Return $GUI_RUNDEFMSG
    EndFunc   ;==>WM_COMMAND
     
    Func _GUICtrlSetState($nCtrl, $iState)
        If BitAND(GUICtrlGetState($nCtrl), $iState) <> $iState Then GUICtrlSetState($nCtrl, $iState)
    EndFunc


    ----------
    ViSiToR a.k.a CreatoR
    CreatoR это не ник, CreatoR это стиль жизни!

    Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 23:52 13-09-2008
    Tipulatoid



    Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    ViSiToR
    Many thanks

    Всего записей: 349 | Зарегистр. 22-12-2006 | Отправлено: 04:58 14-09-2008
    Maza Faka



    Advanced Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    ViSiToR
    Tipulatoid
    Неплохой пример создания Wizard GUI. Но мне не нравится в нём одно свойство, когда я запускаю мастера или выбираю какой-либо элемент, то главное окно выглядит деактивизированным, что портит весь эффект. Поискав в сети, нашёл кое-какие решения. Предлагаю вашему вниманию:
    Подробнее...

    Всего записей: 1420 | Зарегистр. 25-10-2006 | Отправлено: 10:27 14-09-2008 | Исправлено: Maza Faka, 11:28 14-09-2008
    ViSiToR



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    Maza Faka 10:27 14-09-2008
    Цитата:
     не нравится в нём одно свойство

    Мне тоже
     

    Цитата:
    Предлагаю вашему вниманию

    Отличное решение, спасибо.
     
    Кстати, этот Wizard можно и подругому написать, например создавать всё в одном окне, и отображать только нужные элементы на определённых этапах, но это скорее всего потребует больше кодинга, позже если будет время попробую написать.

    ----------
    ViSiToR a.k.a CreatoR
    CreatoR это не ник, CreatoR это стиль жизни!

    Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 15:08 14-09-2008
    bornbill



    Advanced Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    народ может кто поделится простым примером?
    задача разделена на 4 части
     
    1. полученние данных А1 каждые 30 сек
    2. получение данных Б1 каждые 8 сек
    3. Обработка данных А1 если накопилось более двух сборов
    4. Обработка данных Б1 если накопилось более 8 сборов
     
    хотелось бы сделать одной задачей но так сказать в несколько потоков, как это реализовать заранее благодарен.
     
    зы получение и обработка уже отработанные задачи тоесть как их делать я знаю и умею интересует только как всё вместе...
    да и хотелось бы если время 1. будет равно времени начала выполнения 2. то выполнить вначале 1 потом 2....

    Всего записей: 1433 | Зарегистр. 02-04-2004 | Отправлено: 17:32 14-09-2008 | Исправлено: bornbill, 17:35 14-09-2008
    ViSiToR



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    15:08 14-09-2008
    Цитата:
    позже если будет время попробую написать

    Вот:
     

    Код:
    #include <GuiConstantsEx.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>
    ;
     
    Global $Img_Path = @SystemDir & "\oobe\images\wpakey.jpg" ;@SystemDir & "\Setup.bmp"
    Global $iStep = 1
     
    $Main_GUI = GUICreate("Wizard Demo!", 400, 300)
     
    _GUICtrlCreateSeperator(0, 2, 265, 3, 396)
     
    $Back_Button = GUICtrlCreateButton("<<Back", 170, 270, 60)
    GUICtrlSetState(-1, $GUI_DISABLE)
    $Next_Button = GUICtrlCreateButton("Next>>", 240, 270, 60)
     
    $Exit_Button = GUICtrlCreateButton("Exit", 325, 270, 60)
     
    ;Step 1
    $Pic_Step1 = GUICtrlCreatePic($Img_Path, 2, 2, 160, 263, $SS_SUNKEN, $WS_EX_STATICEDGE+$WS_EX_CLIENTEDGE)
    $Label_Step1 = GUICtrlCreateLabel("Wellcome!", 240, 20, 150)
    GUICtrlSetFont(-1, 12, 800)
     
    ;Step 2
    $Input_Step2 = GUICtrlCreateInput("Some input", 10, 20, 180, 20)
    $CheckBox_Step2 = GUICtrlCreateCheckbox("Some checkbox", 10, 50)
     
    ;Step 3
    $Edit_Step3 = GUICtrlCreateEdit("Some Edit", 10, 20, 180, 220)
    $Label_Step3 = GUICtrlCreateLabel("Some Label", 220, 20)
     
    _Elements_SetState($Input_Step2, $Label_Step3, $GUI_HIDE)
     
    GUISetState(@SW_SHOW, $Main_GUI)
     
    While 1
        $Msg = GUIGetMsg()
     
        Switch $Msg
            Case $GUI_EVENT_CLOSE, $Exit_Button
                If $iStep > 1 Then
                    $Ask = MsgBox(256+52, "Attention", "Are you sure you want to exit the Wizard now?", 0, $Main_GUI)
                    If $Ask <> 6 Then ContinueLoop
                EndIf
     
                Exit
            Case
    $Next_Button
                $iStep
    += 1
     
                Switch $iStep
                    Case 2
                        _Elements_SetState($Pic_Step1, $Label_Step1, $GUI_HIDE)
                        _Elements_SetState($Input_Step2, $CheckBox_Step2, $GUI_SHOW)
     
                        GUICtrlSetState($Back_Button, $GUI_ENABLE)
                    Case 3
                        _Elements_SetState($Input_Step2, $CheckBox_Step2, $GUI_HIDE)
                        _Elements_SetState($Edit_Step3, $Label_Step3, $GUI_SHOW)
     
                        GUICtrlSetState($Next_Button, $GUI_DISABLE)
                EndSwitch
            Case $Back_Button
                $iStep -= 1
     
                Switch $iStep
                    Case 2
                        _Elements_SetState($Edit_Step3, $Label_Step3, $GUI_HIDE)
                        _Elements_SetState($Input_Step2, $CheckBox_Step2, $GUI_SHOW)
     
                        GUICtrlSetState($Next_Button, $GUI_ENABLE)
                    Case 1
                        _Elements_SetState($Input_Step2, $CheckBox_Step2, $GUI_HIDE)
                        _Elements_SetState($Pic_Step1, $Label_Step1, $GUI_SHOW)
     
                        GUICtrlSetState($Back_Button, $GUI_DISABLE)
                        GUICtrlSetState($Next_Button, $GUI_ENABLE)
                EndSwitch
        EndSwitch
    WEnd
     
    Func _GUICtrlCreateSeperator($Direction, $Left, $Top, $Width=3, $Lenght=25)
        Switch $Direction
            Case 0
                GUICtrlCreateLabel("", $Left, $Top, $Lenght, $Width, $SS_SUNKEN)
            Case 1
                GUICtrlCreateLabel("", $Left, $Top, $Width, $Lenght, $SS_SUNKEN)
        EndSwitch
    EndFunc
     
    Func _Elements_SetState($iFirstCtrlID, $iLastCtrlID, $iState)
        For $i = $iFirstCtrlID To $iLastCtrlID
            GUICtrlSetState($i, $iState)
        Next
    EndFunc

     
    Добавлено:
    bornbill 17:32 14-09-2008
    Цитата:
    задача разделена на 4 части

    Задача не ясна, что такое А1, Б1 и т.д?

    ----------
    ViSiToR a.k.a CreatoR
    CreatoR это не ник, CreatoR это стиль жизни!

    Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 17:38 14-09-2008 | Исправлено: ViSiToR, 17:43 14-09-2008
    bornbill



    Advanced Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    млин ну данные приходят просто данные откуда с сервера в форме xml документов
    тоесть есть сайт на котором постоянно генерятся новые два файла, изминяються они приблизительно так я указал, хотелось бы их обрабатывать...
     
    тоесть каждая из задач реализованна но хотелось бы потоки сейчас сделано 4 файликами которые каждый выполняют свою роль + блокировка друг друга по файликам тоесть что выполняеться в данный момент а хочет всё засунуть в один процесс, который бы содержал события срабатывающие по таймеру.... скажем так...

    Всего записей: 1433 | Зарегистр. 02-04-2004 | Отправлено: 20:55 14-09-2008
    Hackproof



    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Потоков нема, сами страдаем...

    Всего записей: 106 | Зарегистр. 24-05-2008 | Отправлено: 22:30 14-09-2008
    ViSiToR



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    bornbill
    Выложи скрипты, посмотрим если можно их совместить.

    ----------
    ViSiToR a.k.a CreatoR
    CreatoR это не ник, CreatoR это стиль жизни!

    Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 00:09 15-09-2008
    Maza Faka



    Advanced Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    ViSiToR

    Цитата:
    Вот:

    Да, я думаю, что такое решение лучше предыдущего

    Всего записей: 1420 | Зарегистр. 25-10-2006 | Отправлено: 08:01 15-09-2008
    Pravokonst

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Народ подскажите как задать HomeDir или WorkDir для autoit или приложения которое он запускает?, просто это приложение создаёт мне документы, которые вообще-то не нужны, но лучше скидывать их в папку с этим приложением, перемещение это туповато )

    Всего записей: 7 | Зарегистр. 12-09-2008 | Отправлено: 12:42 15-09-2008
    Maza Faka



    Advanced Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    Pravokonst
    Смотри описание макросов в справке, в разделе Directory macros

    Всего записей: 1420 | Зарегистр. 25-10-2006 | Отправлено: 13:45 15-09-2008
    Pravokonst

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    [q][/q]
    там нельзя задавать, только получать значение

    Всего записей: 7 | Зарегистр. 12-09-2008 | Отправлено: 14:03 15-09-2008
    alex832008

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

    Цитата:
    Код:#include <Array.au3>  
     
    $sIniFile = "BASELIST.ini"  
     
    ;Читаем имена всех секции в файле  
    $aSectNames = IniReadSectionNames($sIniFile)  
     
    If Not @error Then  
        ;Читаем в массив каждую секцию в файле BASELIST.ini  
        For $i = 1 To UBound($aSectNames)-1  
            Assign("aSection_" & $i, IniReadSection($sIniFile, $aSectNames[$i]), 2)  
     
            $aTmpArr = Eval("aSection_" & $i)  
     
            ;Отображаем только что созданный массив содержащий записи текущей секции - для проверки  
            _ArrayDisplay($aTmpArr, "Section: [" & $aSectNames[$i] & "]")  
        Next  
     
        ;Выводим на экран ключ и значение первого элемента в первой секции  
        MsgBox(64, "", $aSection_1[1][0] & "=" & $aSection_1[1][1])  
     
        ;Выводим на экран ключ и значение первого элемента во второй секции  
        MsgBox(64, "", $aSection_2[1][0] & "=" & $aSection_2[1][1])  
     
        ;Теперь каждая переменная $aSection_N содержит массив с секциями, этих переменных столько, сколько секции в ини файле  
        ;Их колчество можно определить по $aSectNames[0]  
        ConsoleWrite($aSectNames[0])  
    EndIf  

     
     
    ViSiToR
     Спасибо за помощь !

    Всего записей: 13 | Зарегистр. 11-09-2008 | Отправлено: 15:07 15-09-2008
    ViSiToR



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    Pravokonst 12:42 15-09-2008
    Цитата:
    как задать HomeDir или WorkDir для autoit или приложения которое он запускает?

    Для самого скрипта используется FileChangeDir(@HomeDrive).
    Для запускаемого приложение используется второй параметр в команде Run:
     

    Код:
     
    FileChangeDir(@HomeDrive)
    Run("SomProgram.exe", @WorkingDir) ;Тут @WorkingDir это @HomeDrive, т.к мы его задали функцией выше


    ----------
    ViSiToR a.k.a CreatoR
    CreatoR это не ник, CreatoR это стиль жизни!

    Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 15:16 15-09-2008
    Pravokonst

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    ViSiToR , спасибо, ты похоже один реально рубишь здесь, или я нифига не понимаю ).

    Всего записей: 7 | Зарегистр. 12-09-2008 | Отправлено: 15:29 15-09-2008
    XpycTMD

    Junior Member
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Подскажите пожалуста как можно сделать такое:
     
    Необходимо при нажатии на кнопку "Печать" вывести диологовое окно выбора принтера, а потом на выбраном принтере распечатать зарание указанный фаил.
     
    Зарание благодарен за помощь.

    Всего записей: 120 | Зарегистр. 17-01-2006 | Отправлено: 15:31 15-09-2008
    ViSiToR



    Silver Member
    Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
    XpycTMD 15:31 15-09-2008
    Цитата:
    Необходимо при нажатии на кнопку "Печать" вывести диологовое окно выбора принтера

     

    Код:
    #include <GuiConstantsEx.au3>
    #include <ButtonConstants.au3>
     
    $sFile = "C:\test.txt"
     
    $GUI = GUICreate("Print Test", 300, 100)
     
    GUICtrlCreateLabel("File Path:", 20, 22)
    $Input = GUICtrlCreateInput($sFile, 80, 20, 200, 20)
     
    $Print_Button = GUICtrlCreateButton("Print", 20, 50, 260, 32, $BS_ICON)
    GUICtrlSetImage(-1, "shell32.dll", -17)
     
    GUISetState(@SW_SHOW, $GUI)
     
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case
    $Print_Button
                $sFile
    = GUICtrlRead($Input)
                Run('Rundll32.exe "' & @SystemDir & '\mshtml.dll",PrintHTML "' & $sFile & '"', @SystemDir)
        EndSwitch
    WEnd


    ----------
    ViSiToR a.k.a CreatoR
    CreatoR это не ник, CreatoR это стиль жизни!

    Всего записей: 3251 | Зарегистр. 01-04-2006 | Отправлено: 16:16 15-09-2008 | Исправлено: ViSiToR, 16:17 15-09-2008
    alex832008

    Newbie
    Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
    Вопрос #2  
    А как легче получать название последней папки в указанном пути FileOpenDialog ?
    т.е. надо название конечной папки вернуть в строку.

    Всего записей: 13 | Зарегистр. 11-09-2008 | Отправлено: 16:31 15-09-2008
    Открыть новую тему    

    Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138

    Компьютерный форум Ru.Board » Компьютеры » Программы » AutoIT (Часть 1)
    Widok (12-01-2009 14:47): лимит страниц. продолжаем здесь


    Реклама на форуме Ru.Board.

    Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
    Modified by Ru.Board
    © Ru.Board 2000-2017

    BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

    Рейтинг.ru