Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Universal Extractor | UniExtractor

Модерирует : gyra, Maz

 Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

Открыть новую тему     Написать ответ в эту тему

addhaloka



Gold Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Код:
@echo off
cls
color 1b
 
:: script for install/reinstall/uninstall UniExtract
:: created by elch
 
setlocal
%~d0
cd "%~dp0"
 
chcp | find "866" >nul
if errorlevel 1 chcp 866 >nul
 
 
:_main
title Меню  инсталляции/деинсталляции  UniExtract
cls
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo               ┌───┬─────────────────────────────────────────┐
echo               │ 1 │   Установить/переустановить UniExtract  │
echo               ├───┼─────────────────────────────────────────┤
echo               │ 2 │ Удалить записи об UniExtract из реестра │
echo               └───┴─────────────────────────────────────────┘
echo.
echo.
set _choice=
set /p _choice=       Нажмите [ENTER] для отмены и выхода или введите вариант [1/2]:  
if "%_choice%" == "" goto _quit
if "%_choice%" == "1" goto _inst
if "%_choice%" == "2" goto _uninst
goto _main
 
:_inst
title Установка  UniExtract
cls
reg add HKLM\SOFTWARE\Classes\exefile\shell\uniextract_sub /ve /d "Извлечь с помощью UniExtract" /f >nul
reg add HKLM\SOFTWARE\Classes\exefile\shell\uniextract_sub /v Icon /d "%cd%\UniExtract.exe,0" /f >nul
reg add HKLM\SOFTWARE\Classes\exefile\shell\uniextract_sub\command /ve /d \""%cd%\UniExtract.exe\" \"%%1\" /sub" /f >nul
reg add HKLM\SOFTWARE\Classes\Msi.Package\shell\uniextract_sub /ve /d "Извлечь с помощью UniExtract" /f >nul
reg add HKLM\SOFTWARE\Classes\Msi.Package\shell\uniextract_sub /v Icon /d "%cd%\UniExtract.exe,0" /f >nul
reg add HKLM\SOFTWARE\Classes\Msi.Package\shell\uniextract_sub\command /ve /d \""%cd%\UniExtract.exe\" \"%%1\" /sub" /f >nul
reg query HKLM\SOFTWARE\Classes | find /i "WinRAR" >nul
if not errorlevel 1 (
    reg add HKLM\SOFTWARE\Classes\WinRAR\shell\uniextract_sub /ve /d "Извлечь с помощью UniExtract" /f >nul
    reg add HKLM\SOFTWARE\Classes\WinRAR\shell\uniextract_sub /v Icon /d "%cd%\UniExtract.exe,0" /f >nul
    reg add HKLM\SOFTWARE\Classes\WinRAR\shell\uniextract_sub\command /ve /d \""%cd%\UniExtract.exe\" \"%%1\" /sub" /f >nul
    )
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\UniExtract.exe" /ve /d "%cd%\UniExtract.exe" /f >nul
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\UniExtract.exe" /v Path /d "%cd%" /f >nul
echo.
echo.
echo.
echo.
echo    Установка UniExtract завершена. Для выхода нажмите любую клавишу ...
pause >nul
goto _quit
 
:_uninst
title Удаление  UniExtract
cls
reg delete HKLM\SOFTWARE\Classes\exefile\shell\uniextract_sub /f >nul
reg delete HKLM\SOFTWARE\Classes\Msi.Package\shell\uniextract_sub /f >nul
reg query HKLM\SOFTWARE\Classes | find /i "WinRAR" >nul
if not errorlevel 1 reg delete HKLM\SOFTWARE\Classes\WinRAR\shell\uniextract_sub /f >nul
reg query HKCU\Software | find /i "UniExtract" >nul
if not errorlevel 1 reg delete HKCU\Software\UniExtract /f >nul
reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths" | find /i "UniExtract.exe" >nul
if not errorlevel 1 reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\UniExtract.exe" /f >nul
echo.
echo.
echo.
echo.
echo     Удаление UniExtract завершено. Для выхода нажмите любую клавишу ...
pause >nul
goto _quit
 
:_quit
endlocal
exit

Всего записей: 7432 | Зарегистр. 13-11-2010 | Отправлено: 09:54 16-09-2013
Открыть новую тему     Написать ответ в эту тему

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Universal Extractor | UniExtractor


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru