Wozik
Ёж | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Код: @echo off
setlocal enabledelayedexpansion
tasklist | findstr "BlueSoleilCS.exe" || goto:not
::BlueSoleilCS.exe found
SET "choice="
SET /P "choice=BlueSoleil Stop?(Y/N): "
IF /i "!choice!" equ "n" GOTO:EOF
TASKKILL /F /t /IM BlueSoleil.exe
TASKKILL /F /t /IM BlueSoleilCS.exe
TASKKILL /F /t /IM BsHelpCS.exe
TASKKILL /F /t /IM BsMobileCS.exe
TASKKILL /F /t /IM BtTray.exe
call:getbs
if "%BS%" neq "0x4" (
SET "choice="
SET /P "choice=Disable Autostart BlueSoleil ? (Y/N): "
IF /i "!choice!" equ "n" GOTO:EOF
sc config BsHelpCS start= disabled
sc config BlueSoleilCS start= disabled
sc config BsMobileCS start= disabled
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\ /v BtTray /f
)
goto:eof
:not
::BlueSoleilCS.exe not found
call:getbs
if "%BS%" neq "0x4" goto:bttray
sc config BsHelpCS start= demand
sc config BlueSoleilCS start= auto
sc config BsMobileCS start= auto
REG ADD HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\ /v BtTray /d "\"C:\Program Files\IVT Corporation\BlueSoleil\BtTray.exe\""
:bttray
start "" "C:\Program Files\IVT Corporation\BlueSoleil\BtTray.exe"
goto:eof
:getbs
for /f "tokens=2,*" %%a in ('REG QUERY HKLM\SYSTEM\CurrentControlSet\Services\BlueSoleilCS /v Start ^| findstr "Start" ') do set "BS=%%~b"
exit /b |
|
Всего записей: 589 | Зарегистр. 02-01-2003 | Отправлено: 14:28 01-12-2006 | Исправлено: Komandor, 15:06 25-06-2016 |
|
