#include <GuiConstantsEx.au3>
;
Global $hGUI_1, $hGUI_2, $hGUI_3
Global $nGUI_1_Button, $nGUI_2_Checkbox, $nGUI_3_Button, $nGUI_3_Input
Opt("TrayMenuMode", 1)
Opt("TrayOnEventMode", 1)
Opt("GUIOnEventMode", 1)
TraySetClick(16)
$Func_1_TrayItem = TrayCreateItem("Функция №1")
$Func_2_TrayItem = TrayCreateItem("Функция №2")
$Func_3_TrayItem = TrayCreateItem("Функция №3")
TrayCreateItem("")
$Exit_TrayItem = TrayCreateItem("Exit")
For $iItem = $Func_1_TrayItem To $Exit_TrayItem
TrayItemSetOnEvent($iItem, "_Tray_Events")
Next
_GUICreate_Func_1()
_GUICreate_Func_2()
_GUICreate_Func_3()
While 1
Sleep(100)
WEnd
Func _Tray_Events()
Switch @TRAY_ID
Case $Exit_TrayItem
Exit
Case $Func_1_TrayItem
GUISetState(@SW_SHOW, $hGUI_1)
Case $Func_2_TrayItem
GUISetState(@SW_SHOW, $hGUI_2)
Case $Func_3_TrayItem
GUISetState(@SW_SHOW, $hGUI_3)
EndSwitch
EndFunc
Func _GUI_Events()
Switch @GUI_CtrlId
Case $GUI_EVENT_CLOSE
GUISetState(@SW_HIDE, @GUI_WinHandle)
Case $nGUI_1_Button
;MsgBox(64, "Инфо", "Вы нажали Кнопку.", 0, $hGUI_1)
ToolTip("Вы нажали Кнопку.", -1, -1, "Инфо", 1)
Case $nGUI_2_Checkbox
Local $sCheckbox_Data = "Вы сняли отметку с галочки."
If GUICtrlRead($nGUI_2_Checkbox) = $GUI_CHECKED Then $sCheckbox_Data = "Вы поставили отметку на галочке."
;MsgBox(64, "Инфо", $sCheckbox_Data, 0, $hGUI_2)
ToolTip($sCheckbox_Data, -1, -1, "Инфо", 1)
Case $nGUI_3_Button
;MsgBox(64, "Инфо", "Вы ввели: " & GUICtrlRead($nGUI_3_Input), 0, $hGUI_3)
ToolTip("Вы ввели: " & GUICtrlRead($nGUI_3_Input), -1, -1, "Инфо", 1)
EndSwitch
EndFunc
Func _GUICreate_Func_1()
$hGUI_1 = GUICreate("Функция №1", 300, 120, 350, 150)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_Events")
$nGUI_1_Button = GUICtrlCreateButton("Кнопка", 20, 40, 60, 20)
GUICtrlSetOnEvent(-1, "_GUI_Events")
EndFunc
Func _GUICreate_Func_2()
$hGUI_2 = GUICreate("Функция №2", 300, 120, 350, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_Events")
$nGUI_2_Checkbox = GUICtrlCreateCheckbox("Галочка", 20, 40, 60, 20)
GUICtrlSetOnEvent(-1, "_GUI_Events")
EndFunc
Func _GUICreate_Func_3()
$hGUI_3 = GUICreate("Функция №3", 300, 120, 350, 450)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_Events")
$nGUI_3_Input = GUICtrlCreateInput("Строка", 20, 10, 260, 20)
$nGUI_3_Button = GUICtrlCreateButton("Показать ввод", 20, 40, 120, 20)
GUICtrlSetOnEvent(-1, "_GUI_Events")
EndFunc |
