SLasH
Advanced Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
sasha300
FoxitReader мне перестал нравится, когда я познакомился с PDF-XChange Viewer
Для ассоциации использую переделанный BAT-ник из папки .Extra:
__ext.bat
Код: @echo off
chcp 1251 > nul
:: @param1: "exeFile"
if [%1]==[] call :errMsg & goto :EOF
:: @param2: "ext"
if [%2]==[] call :errMsg & goto :EOF
:: @param3: "extName"
if [%3]==[] call :errMsg & goto :EOF
:: @param4: "extDesc"
if [%4]==[] call :errMsg & goto :EOF
:: @param5: "iconFileFullName"
if [%5]==[] call :errMsg & goto :EOF
set exeFile="%~1"
:: Регистрируемое расширение
set ext="%~2"
:: Название типа в системе (не видимо для пользователя): ThinApp Word 2007.Document
set extName="%~3"
:: Название типа в системе (видимо для пользователя): Word 2007 Document
set extDesc="%~4"
:: Файл иконки
set iconFile="%~5"
:: Номер иконки
set iconIndex="%~6"
::call :infoMsg "exeFile=%exeFile:~1,-1%" "ext=%ext:~1,-1%" "extName=%extName:~1,-1%" "extDesc=%extDesc:~1,-1%" "iconFile=%iconFile:~1,-1%" "iconIndex=%iconIndex:~1,-1%"
::goto :EOF
reg add "HKCR\.%ext:~1,-1%" /ve /d %extName% /f > nul
reg add "HKCR\%extName:~1,-1%" /ve /d %extDesc% /f > nul
if not "%iconIndex%"=="" (
reg add "HKCR\%extName:~1,-1%\DefaultIcon" /ve /d "%iconFile:~1,-1%,%iconIndex:~1,-1%" /f > nul
) else (
reg add "HKCR\%extName:~1,-1%\DefaultIcon" /ve /d "%iconFile:~1,-1%" /f > nul
)
reg add "HKCR\%extName:~1,-1%\shell" /ve /d "open" /f > nul
reg add "HKCR\%extName:~1,-1%\shell\open\command" /ve /d "\"%exeFile:~1,-1%\" \"%%1\"" /f > nul
reg add "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Extensions" /v %ext% /d "\"%exeFile:~1,-1%\" ^.%ext:~1,-1%" /f > nul
goto :EOF
::==[ Functions ]===============================================================
::--[ InfoMessage ]-------------------------------------------------------------
:infoMsg
setlocal ENABLEDELAYEDEXPANSION
echo [%~nx0]: Info :: arguments
set "count=1"
for %%i IN (%*) do (
echo [ %%!count! ] =^> %%i
set /a "count+=1"
)
pause
exit /b 0
::--[ ErrorMessage ]------------------------------------------------------------
:errMsg
echo --[ %~nx0 ]: ERROR --------------------------------------------------------
echo Использование скрипта:
echo @param1: "exeFile"
echo @param2: "ext"
echo @param3: "extName"
echo @param4: "extDesc"
echo @param5: "iconFile"
echo @param6: "iconIndex"
echo ---------------------------------------------------------------------------
echo Пример: %~nx0 "D:\Office\Word 2007.exe" "doc" "ThinApp Word 2007.Document" "Word 2007 Document" "D:\Office\Word 2007.exe" "1"
pause
exit /b 0 |
!ext-reg.bat
Код: @echo off
set exeFullName="%~dp0ghostexp.exe"
set ext="gho"
set extName="%ext:~1,-1%.Symantec Ghost"
set extDesc="Symantec Ghost Image"
set iconFileFullName=%exeFullName%
set iconIndex="0"
call "%~dp0__ext.bat" %exeFullName% %ext% %extName% %extDesc% %iconFileFullName% %iconIndex%
|
Для каждой программы создаётся свой !ext-reg.bat, а он вызывает __ext.bat |
Всего записей: 723 | Зарегистр. 08-10-2002 | Отправлено: 11:20 09-04-2013 | Исправлено: SLasH, 11:22 09-04-2013 |
|
