Командная строка, батники, сценарии (bat, cmd) - [2051] :: Программы

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
ECHO DLC Item Transfer Patch (v1.11) by Mad Method
ECHO.
ECHO This batch script will automatically patch all DLC content to transfer properly
ECHO to DAO Awakening. If you are running this on top of an older fix, you should
ECHO undo the previous fix first.
ECHO.
PAUSE
ECHO.
FOR /F "TOKENS=2*" %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v Personal') DO SET AP="%%B"
CALL SET AP=%AP:~,-1%\BioWare\Dragon Age\AddIns"
%AP:~1,2%
CD %AP%
FOR %%A IN (cp_1 cp_2 cp_3 cp_7 nrx_1) DO IF EXIST dao_prc_%%A\. CALL :FDT "dao_prc_%%A"
FOR %%A IN (1 2 3 4 5 c2 edg emb hod lks lnp me vgl war wkd btk pan gbk) DO IF EXIST dao_prc_promo_%%A\. CALL :FDT "dao_prc_promo_%%A"
ECHO.
ECHO Done.
SET /P T=Press any key to exit.<NUL
PAUSE>NUL
GOTO :EOF
:FDT
SET /P T=Fixing %*... <NUL
CD %*
SET MN=%*
SET MNL=0
:SL
SET /A MNL+=1
IF NOT "!MN:~%MNL%,1!"=="" GOTO :SL
SET /A MNL-=1
IF NOT EXIST core\. ECHO Error: There is no "core" folder in the AddIn?!&GOTO :EF
IF NOT EXIST module\. ECHO Error: There is no "module" folder in the AddIn?!&GOTO :EF
MD core\override\DLC_FIX\talktables 2>NUL
FOR %%A IN (module\data\*.*) DO COPY /Y "%%A" "core\override\DLC_FIX\%%~nA2%%~xA">NUL
FOR %%A IN (module\data\talktables\*.*) DO CALL :RT "%%A"
IF NOT EXIST module\audio\sound\. GOTO :GEF
MD core\override\DLC_FIX\sound 2>NUL
COPY /Y module\audio\sound\*.* core\override\DLC_FIX\sound\>NUL
:GEF
ECHO Fixed.
:EF
CD..
GOTO :EOF
:RT
SET F=%~n1
FOR %%A IN (cp_1 cp_2 promo_1 promo_btk promo_pan promo_gbk) DO IF %MN%=="dao_prc_%%A" COPY %* "core\override\DLC_FIX\talktables\">NUL&GOTO :EOF
COPY %* "core\override\DLC_FIX\talktables\%MN%_c_!F:~%MNL%!.tlk">NUL

Модерирует : gyra, Maz
articlebot (21-06-2016 11:40): Следующая часть - Командная строка, батники, сценарии (bat, cmd)	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению