Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Total Commander (Часть 7)

Модерирует : gyra, Maz

articlebot (19-12-2012 23:27): переезжаем в новую тему, Часть 8  Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

   

Rodny



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Код:
'==============================================================================
' В активной файловой панели TC открывает папку,  
' полный путь которой отличается от папки в соседней файловой панели только буквой диска.
' http://forum.ru-board.com/topic.cgi?forum=5&topic=25394&start=1600#7
'  
' Параметры вызова:
' "%T" {какую букву диска подставлять}
'
' Пример параметров в кнопке для вызова из TC:
' "%T" G
'  
' Если второй параметр не задан, выводится запрос.
'
' Автор - Rodny
'==============================================================================
Option Explicit
Dim WSH, FSO, DiskLetter, TargetPath, NewPath
 
Set WSH = CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
 
' Получаем текущий путь в соседней панели
TargetPath = WSH.ExpandEnvironmentStrings(WScript.Arguments(0))
' Проверяем количество параметров в кнопке и задаём букву диска
If WScript.Arguments.Count = 1 Then
    DiskLetter = InputBox("Введите букву диска", "Нужно указать букву диска")
Else
    DiskLetter = WScript.Arguments(1)
End If
 
' Составляем новый путь
If DiskLetter <> "" Then
    NewPath = DiskLetter & Right(TargetPath, Len(TargetPath)-1)
Else
    MsgBox "Буква диска не задана, что Вам нужно - я не знаю.", vbOKOnly + vbExclamation, "Внимание!"
    WScript.Quit
End If
 
' Если такая папка существует, открываем
If FSO.FolderExists(NewPath) Then
    WSH.Run WSH.ExpandEnvironmentStrings("%COMMANDER_PATH%\totalcmd.exe") & " /O /S /L=" & NewPath
Else
    MsgBox "Папки " & """" & NewPath & """" & " не существует!", vbOKOnly + vbExclamation, "Внимание!"
End If
 
Set WSH = Nothing
Set FSO = Nothing
WScript.Quit

Всего записей: 2877 | Зарегистр. 28-07-2006 | Отправлено: 23:59 09-02-2011 | Исправлено: Rodny, 00:17 10-02-2011
   

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Total Commander (Часть 7)
articlebot (19-12-2012 23:27): переезжаем в новую тему, Часть 8


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru