Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » 360 Extreme Explorer (и другие браузеры компании 360 (Qihoo)

Модерирует : gyra, Maz

gyra (06-02-2018 10:47): 360 Extreme Explorer (и другие браузеры компании 360 (Qihoo)  Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

   

virjokk

Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Создаем батник с нижеследующим содержимым, кладем его рядом со скачанными дистрибутивом 360ЕЕ и русификатором от WatsonRus.
Сюда же поместить патч из шапки для изменения магазина и поисковика. При необходимости он будет применен.
Если каталога с портабельной версией 360EE еще нет, создаем его с такой структурой: 360Chrome\Chrome\application,  
и в переменной "ее" указываем путь к нему (напр, c:\program files\360Chrome\Chrome\application).
В переменной "sz" - путь к 7-ZIP (напр., c:\program files\7-zip\7z.exe). Исправьте в батнике пути, если они у вас другие.
Выполняем батник с правами администратора. В WinXP не работает.
Для обновления версии 360ЕЕ запускаем батник со свежими сборкой и русификатором.  
Для параноиков: раскомментируйте две закомментированные строки
Код:
 
@echo off
cd /d "%~dp0"
set "ee=c:\program files\360Chrome\Chrome\application"
set "sz=c:\program files\7-zip\7z.exe"
if not exist "%ee%\" echo Not found 360EE destination folder & exit /b
if not exist "%sz%" echo Not found 7-ZIP archiver & exit /b
if not exist "360chrome*ru*.zip" echo Not found RU package & exit /b
:close
tasklist /fi "IMAGENAME eq 360Chrome.exe" | find /i "360Chrome.exe" >nul && echo Close 360EE && pause && goto :close
if exist "360cse*.exe" (%sz% e -aoa -o%TEMP% "360cse*.exe" "chrome.7z" || exit /b) else (echo Not found 360EE installer & exit /b)
if exist "%TEMP%\360EERU\" rd /s /q "%TEMP%\360EERU"
%sz% x -o%TEMP%\360EERU "360chrome*ru*.zip" || exit /b
set "eelst=%TEMP%\eelist.txt"
echo installer> "%eelst%"
REM echo download>> "%eelst%"
echo 360BDoctorExt>> "%eelst%"
echo itrusenroll.dll>> "%eelst%"
echo npaliedit.dll>> "%eelst%"
echo npAliSecCtrl.dll>> "%eelst%"
echo npalissologin.dll>> "%eelst%"
echo npcombrg.dll>> "%eelst%"
echo pta.dll>> "%eelst%"
echo safe505.dll>> "%eelst%"
echo sesafe.dll>> "%eelst%"
echo smartpreheat.dat>> "%eelst%"
echo smart_preheat.dll>> "%eelst%"
echo smartpreheat64.dll>> "%eelst%"
echo 360bdoctor.exe>> "%eelst%"
echo updatecfg.ini>> "%eelst%"
echo navhome.htm>> "%eelst%"
if exist "%TEMP%\chrome-bin\" rd /s /q "%TEMP%\chrome-bin"
%sz% x -o%TEMP% -xr@%eelst% "%TEMP%\chrome.7z" || del /f /q %eelst% && rd /s /q "%TEMP%\360EERU" && exit /b
for /f "delims=" %%i in ('2^>nul dir /b /a:d "%TEMP%\chrome-bin" ^| findstr "[0-9]*\.[0-9]*\.[0-9]*.*"') do (set eetemp=%%i)
if "%eetemp%"=="" echo Not found unpacked 360EE & del /f /q %eelst% & rd /s /q "%TEMP%\360EERU" & exit /b
%sz% d "%TEMP%\chrome-bin\components\download\download.7z" xlbug* -r >nul 2>&1
for /f "delims=" %%i in ('2^>nul dir /b /a:d "%ee%" ^| findstr "[0-9]*\.[0-9]*\.[0-9]*.*"') do (rd /s /q "%ee%\%%i")
robocopy "%TEMP%\chrome-bin" "%ee%" /e
robocopy "%TEMP%\360EERU" "%ee%\%eetemp%" /e
for /f "tokens=1-4 delims=." %%I in ("%eetemp%") do (
if %%J NEQ 0 if %%L GEQ 120 for %%I in (*fix*.exe) do (%%~fI /silent /overwrite /startupworkdir "%ee%\%eetemp%"& echo. & echo.)
)
REM rd /s /q "%ee%\components\download" >nul 2>&1 & copy /y nul "%ee%\components\download"
rd /s /q "%TEMP%\chrome-bin","%TEMP%\360EERU"
del /f /q "%TEMP%\chrome.7z","%eelst%"
echo 360EE v%eetemp% was installed in portable mode
 


Всего записей: 288 | Зарегистр. 19-05-2006 | Отправлено: 09:18 27-06-2017 | Исправлено: virjokk, 13:49 04-02-2018
   

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » 360 Extreme Explorer (и другие браузеры компании 360 (Qihoo)
gyra (06-02-2018 10:47): 360 Extreme Explorer (и другие браузеры компании 360 (Qihoo)


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru