xrun1
Advanced Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
@echo off
set "valSetting=Текущие настройки:"
set "valSetting1=Вроде, эта настройка не работает, но пусть будет..."
set "valueLoad="
:_begin_
cls
call :check 0
echo.
echo Разрешить или запретить проверку update драйверов?
echo.
choice /c 123 /n /m "1 - Запретить, 2 - Разрешить, 3 - Выход."
if "%errorlevel%" == "3" goto :EOF
if "%errorlevel%" == "2" (
echo Выбрано - Разрешить
echo.
reg add "HKLM\SOFTWARE\MICROSOFT\WINDOWS\CURRENTVERSION\DRIVERSEARCHING" /v SearchOrderConfig /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Device Metadata" /v PreventDeviceMetadataFromNetwork /t REG_DWORD /d 0 /f
reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /v ExcludeWUDriversInQualityUpdate /t REG_DWORD /d 0 /f
call :check 1 1
call :mmc 2
goto _begin_
)
if "%errorlevel%" == "1" (
echo Выбрано - Запретить
echo.
reg add "HKLM\SOFTWARE\MICROSOFT\WINDOWS\CURRENTVERSION\DRIVERSEARCHING" /v SearchOrderConfig /t REG_DWORD /d 0 /f
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Device Metadata" /v PreventDeviceMetadataFromNetwork /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /v ExcludeWUDriversInQualityUpdate /t REG_DWORD /d 1 /f
call :check 1 2
call :mmc 1
goto _begin_
)
:check
setlocal
echo.
if %1 == 1 (TIMEOUT /T %2 /NOBREAK & exit /b)
for /f "tokens=3*" %%i in (' reg query "HKLM\SOFTWARE\MICROSOFT\WINDOWS\CURRENTVERSION\DRIVERSEARCHING" /v SearchOrderConfig 2^>nul ') do set valueLoad=%%i
echo %valSetting%
echo.
if "%valueLoad%" == "0x0" echo Запрещено - Система -^> Диспетчер устройств
if "%valueLoad%" == "0x1" echo Разрешено - Система -^> Диспетчер устройств
echo.
for /f "tokens=3*" %%i in (' reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Device Metadata" /v PreventDeviceMetadataFromNetwork 2^>nul ') do set valueLoad=%%i
if "%valueLoad%" == "0x0" echo Разрешено - Система -^> Доп. параметры системы -^> Оборудование -^> Параметры установки устройств
if "%valueLoad%" == "0x1" echo Запрещено - Система -^> Доп. параметры системы -^> Оборудование -^> Параметры установки устройств
echo %valSetting1%
echo.
for /f "tokens=3*" %%i in (' reg query "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /v ExcludeWUDriversInQualityUpdate 2^>nul ') do set valueLoad=%%i
if "%valueLoad%" == "0x0" echo Разрешено - ГП -^> Конф. компьютера -^> Адм. шаблоны -^> Комп-ты Windows -^> Центр обновл. -^> Не вкл. драйверы в обновления Windows
if "%valueLoad%" == "0x1" echo Запрещено - ГП -^> Конф. компьютера -^> Адм. шаблоны -^> Комп-ты Windows -^> Центр обновл. -^> Не вкл. драйверы в обновления Windows
endlocal
exit /b
:mmc
setlocal
tasklist.exe /nh /fi "imagename eq mmc.exe" /fi "windowtitle eq Диспетчер устройств" | find.exe /I "mmc.exe"
if %1 == 2 (
if %ERRORLEVEL% NEQ 0 start "C:\Windows\System32\mmc.exe" C:\Windows\system32\devmgmt.msc
) else (
if %ERRORLEVEL% EQU 0 taskkill.exe /fi "windowtitle eq Диспетчер устройств" /im mmc.exe
)
endlocal
exit /b
|
Всего записей: 720 | Зарегистр. 26-12-2009 | Отправлено: 02:40 21-09-2022 | Исправлено: xrun1, 04:52 21-09-2022 |
|
