@echo off
title "Запрет обновлений Firefox 63+"
color 1B
set "FFupdate="
set "vFF="
for /f "tokens=2*" %%i in ('reg query "HKLM\SOFTWARE\Policies\Mozilla\Firefox" /v DisableAppUpdate') do set "FFupdate=%%j"
if not Defined FFupdate cls
for /f "tokens=2*" %%i in ('reg query "HKLM\SOFTWARE\Mozilla\Mozilla Firefox" /v CurrentVersion') do set "vFF=%%j"
tasklist.exe /nh /fi "imagename eq firefox.exe" | find.exe /I "firefox.exe" > nul || goto M0
echo.
call :write 1C "Firefox выполняется" 22
call :writeLn 1C " требуется перезапуск после изменения параметров реестра"
:M0
echo.
call :write 1B "Состояние Mozilla Firefox Update Version" 22
call :writeLn 1A " %vFF%"
if not Defined FFupdate goto M1
if "%FFupdate%" == "0x1" call :writeLn 1E "ЗАПРЕЩЕНО"
echo.
echo -----------------------------------------------------
echo 1 - разрешить
echo 0 - выход (или нажать Enter)
echo -----------------------------------------------------
set /P "uFF=Введите команду, нажмите Enter: " || set "uFF=0"
if %uFF% ==1 reg delete "HKLM\SOFTWARE\Policies\Mozilla\Firefox" /v DisableAppUpdate /f
if %uFF% ==0 (echo Выход!) else if not %uFF% ==1 goto beep
goto M2
:M1
call :writeLn 1E "НЕ ЗАПРЕЩЕНО"
echo.
echo -----------------------------------------------------
echo 2 - запретить
echo 0 - выход (или нажать Enter)
echo -----------------------------------------------------
set /P "uFF=Введите команду, нажмите Enter: " || set "uFF=0"
if %uFF% ==2 reg add "HKLM\SOFTWARE\Policies\Mozilla\Firefox" /v DisableAppUpdate /t REG_DWORD /d 1
if %uFF% ==0 (echo Выход!) else if not %uFF% ==2 goto beep
goto M2
:beep
0<nul set /p strTemp=
color 4B
echo.
echo Неверное значение, операция не выполнена, выход.
:M2
TIMEOUT /T 3 /NOBREAK
goto :EOF
:write
setlocal
:write1
set "tempFolder=%TEMP%\%~n0.%time:~-2%.%random%"
md "%tempFolder%" 2>nul || goto write1
pushd %tempFolder%
set /p .=.<nul>"%~2"
findstr /a:%~1 /c:"." /s "%~2"
if "%~3"=="" (set /p .= <nul) else set /p .= <nul
popd
rd /s /q "%tempFolder%" 2>nul
endlocal & exit /b
:writeLn
call :write %1 "%~2" %3
echo.
exit /b
========================================= https://forum.mozilla-russia.org/viewtopic.php?pid=771231#p771231
1. Создать каталог distribution по пути: C:\Program Files\Mozilla Firefox. В портабельных ...\FirefoxPortable\App\Firefox (Firefox64)
Создать файл policies.json, добавить код и поместить в папку distribution.
скрытый текст
Выделить код
Код:
{
"policies": {
"DisableAppUpdate": true
}
}
|
