Командная строка, батники, сценарии (bat, cmd) - [3301] :: Программы

Код:

@echo off
rem Windows NT 4.0 or higher?
2>nul verify other & setlocal enableextensions & endlocal & if errorlevel 1 echo Older than Windows NT 4.0

rem Windows 2000 or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & if errorlevel 1 echo Older than Windows 2000

rem Windows XP or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & (if not errorlevel 1 color 00 & if errorlevel 1 (set/a0) else 2>nul verify other) & if errorlevel 1 echo Older than Windows XP

rem Любая проверка ниже выдаст ошибку в Windows NT 3.51. Поэтому предваряем ее
rem проверкой "Windows XP or higher?" и при errorlevel 1 пропускаем выполнение
rem (в реальном скрипте 'goto skip' нужно заменить на 'goto :eof').

rem Windows Vista / Windows Server 2008 or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & (if not errorlevel 1 color 00 & if errorlevel 1 (set/a0) else 2>nul verify other) & if errorlevel 1 echo Older than Windows Vista& goto skip
color 00 & (for /f "delims=[ tokens=2" %%A in ('ver') do for /f "tokens=2 delims=. " %%B in ("%%A") do if %%B GEQ 6 set/a0) & if errorlevel 1 echo Older than Windows Vista
:skip

rem Windows 7 / Windows Server 2008 R2 or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & (if not errorlevel 1 color 00 & if errorlevel 1 (set/a0) else 2>nul verify other) & if errorlevel 1 echo Older than Windows 7& goto skip
color 00 & (for /f "delims=[ tokens=2" %%A in ('ver') do for /f "tokens=2,3 delims=. " %%B in ("%%A") do if %%B GTR 6 (set/a0) else if %%B==6 if %%C GEQ 1 set/a0) & if errorlevel 1 echo Older than Windows 7
:skip

rem Windows 8 / Windows Server 2012 or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & (if not errorlevel 1 color 00 & if errorlevel 1 (set/a0) else 2>nul verify other) & if errorlevel 1 echo Older than Windows 8& goto skip
color 00 & (for /f "delims=[ tokens=2" %%A in ('ver') do for /f "tokens=2,3 delims=. " %%B in ("%%A") do if %%B GTR 6 (set/a0) else if %%B==6 if %%C GEQ 2 set/a0) & if errorlevel 1 echo Older than Windows 8
:skip

rem Windows 8.1 / Windows Server 2012 R2 or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & (if not errorlevel 1 color 00 & if errorlevel 1 (set/a0) else 2>nul verify other) & if errorlevel 1 echo Older than Windows 8.1& goto skip
color 00 & (for /f "delims=[ tokens=2" %%A in ('ver') do for /f "tokens=2,3 delims=. " %%B in ("%%A") do if %%B GTR 6 (set/a0) else if %%B==6 if %%C GEQ 3 set/a0) & if errorlevel 1 echo Older than Windows 8.1
:skip

rem Windows 10 / Windows Server 2016 or higher?
2>nul verify other & 2>nul setlocal disabledelayedexpansion & endlocal & (if not errorlevel 1 color 00 & if errorlevel 1 (set/a0) else 2>nul verify other) & if errorlevel 1 echo Older than Windows 10& goto skip
color 00 & (for /f "delims=[ tokens=2" %%A in ('ver') do for /f "tokens=2 delims=. " %%B in ("%%A") do if %%B GEQ 10 set/a0) & if errorlevel 1 echo Older than Windows 10
:skip

Модерирует : gyra, Maz
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению