Viktor_Kisel
Silver Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
:: ===================================
:: Тюнинг Avira Free Antivirus
:: ===================================
@echo off
echo Перед запуском скрипта необходимо выключить Real-Time Protection !!!
echo Скрипт запускать под Администратором !!!
echo Нажмите Ctrl/C для прерывания
pause
echo.
:: ===================================
:: Блокируем рекламу Avira (ipmgui.exe)
:: ===================================
for /f "tokens=1 delims=:" %%i in ('findstr /n "ipm.avira.com" %WinDir%\System32\drivers\etc\hosts') do goto :Next
echo Блокируем рекламу Avira
echo 127.0.0.1 ipm.avira.com>> %windir%\System32\drivers\etc\hosts
echo Проверяем результат:
type %windir%\System32\drivers\etc\hosts
pause
echo.
:: ===================================
:: Отключаем Avira Launcher (My Avira)
:: ===================================
:Next
echo Завершаем процесс Avira.Systray.exe:
taskkill /im Avira.Systray.exe
pause
echo.
echo 32-bit или 64-bit OS
IF EXIST "%PROGRAMFILES(X86)%" (GOTO 64BIT) ELSE (GOTO 32BIT)
:64BIT
echo Удаляем Avira SystrayStartTrigger из автозагрузки для 64-битных систем:
reg delete HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Run /v "Avira SystrayStartTrigger" /f
GOTO END
:32BIT
echo Удаляем Avira SystrayStartTrigger из автозагрузки для 32-битных систем:
reg delete HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v "Avira SystrayStartTrigger" /f
:END
pause
echo.
echo Останавливаем и отключаем службу Avira Service Host:
sc stop Avira.ServiceHost
sc config Avira.ServiceHost start= disabled
echo Готово !
echo Перезагружаемся и включаем Real-Time Protection !
pause
|
