; http://forum.ru-board.com/topic.cgi?forum=5&topic=49007&start=420#19
link_wait:=10 ; время, которое скрипт хранит скопированный текст до появления окна загрузки, с. В течении этого времени можно нажать следующую ссылку, если исходная ссылается на другую страницу или пункт меню панели скачивания
rename_delay:=1000 ; задержка между появлением окна добавления загрузки и изменением названия файла, мс. Увеличить, если видно, что оригинальное название переписывает назначенное
^+LButton::
MouseGetPos xp, yp
hwnd:=WinActive("A")
KeyWait LButton, T1
KeyWait Ctrl, T1
KeyWait Shift, T1
temp:=Clipboard, Clipboard:=""
Send ^{vk43}
ClipWait 0.5
WinGet, controls, ControlList, A
If controls~="IDM Download Button class1"
ControlClick IDM Download Button class1, ahk_id %hwnd%
else
MouseClick, ,% xp,% yp
Insert:
If new_name:=Clipboard
{
WinWaitActive ahk_class #32770 ahk_exe IDMan.exe, , % link_wait
ControlGetText old_name, Edit3
new_name:=RegExReplace(new_name,"(:|;|,|\.\s+|\R+|\||\*|\?|\\|/|<|>|"")"," ")
new_name:=Trim(RegExReplace(new_name,"\s{2,}"," "))
If (A_ThisHotkey="^+LButton")
Sleep % rename_delay
ControlSetText Edit3
ControlFocus Edit3
SendInput % "{Raw}" RegExReplace(old_name, "\\\K.+?(?=\.\S{2,5}$)",new_name)
}
If (A_ThisHotkey="^+LButton")
Clipboard:=temp
return
#IfWinActive ahk_class #32770 ahk_exe IDMan.exe
^+vk56::goto Insert
#vk5A::Send !{F4}
#IfWinNotActive ahk_class #32770 ahk_exe IDMan.exe
#vk5A::
Run % A_ProgramFiles ((A_Is64bitOS) ? " (x86)" : "") "\Internet Download Manager\IDMan.exe"
WinWait ahk_class #32770 ahk_exe IDMan.exe, , 5
WinActivate
#IfWinActive
|
