xrun1
Advanced Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
@echo off && chcp 65001 > nul
:: Batch-файл для Windows XP+ на основе сценария eddiezato для PowerShell
:: http://forum.ru-board.com/topic.cgi?forum=5&topic=50152&start=760#5
:: Проверьте и измените ваши пути к файлам, если это необходимо
set "YtDl=c:\Program Files\PotPlayer\Module\youtube-dl.exe"
set "DPP=c:\Program Files\PotPlayer\PotPlayerMini64.exe"
:: Если есть URL как параметр запуска
if /I not "%~1" == "" (set "ClipboardData=%~1" && goto NEXT)
:BEGIN
set "ClipboardData=" && set "uUrl=" && set "Choice=" && set "fCount=" && set "fTemp="
:: Получить данные буфера обмена и установить в переменную ClipboardData
for /f "delims=" %%i in ('
mshta "javascript:var x=clipboardData.getData('text');if(x) new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();"
') do set "ClipboardData=%%i"
:NEXT
if Defined ClipboardData (echo %~nx0 --^> Clipboard URL is: "%ClipboardData%" && echo.) else (echo %~nx0 --^> ERROR: Clipboard is empty^! && goto ERROR)
"%YtDl%" -F %ClipboardData%
if %errorlevel% NEQ 0 goto ERROR
set /p "Choice=Choose quality or press Enter for best: " || set "Choice=best"
:FileTemp
set /a fCount+=1
:: 10 попыток создать временный файл с именем датавремя.tmp в папке %TEMP%
if %fCount% GTR 10 (echo %~nx0 --^> ERROR: Unable to create temporary file && goto ERROR)
for /f "tokens=1 delims=." %%i in ('WMIC OS Get LocalDateTime^|Find "."') do set "fTemp=%%i.tmp"
if Exist "%TEMP%\%fTemp%" goto FileTemp
:aQUALITY
:: Запись ссылки во временный файл
"%YtDl%" -g -f %Choice% %ClipboardData% > "%TEMP%\%fTemp%"
if %errorlevel% NEQ 0 (del /f /q "%TEMP%\%fTemp%" && goto ERROR)
:: Присвоить переменной значение ссылки из временного файла и удалить файл
for /f "usebackq tokens=* delims=" %%i in ("%TEMP%\%fTemp%") do set "uUrl=%%i"
del /f /q "%TEMP%\%fTemp%"
if not Defined uUrl (echo %~nx0 --^> ERROR: Quality is not recognized && goto ERROR)
start "" "%DPP%" "%uUrl%"
exit /b 0
:ERROR
echo.
set /p "Choice=[R - Retry, Enter - Exit or Choose another quality]? " || exit /b 1
if /I "%Choice%" == "R" (cls && goto BEGIN) else goto aQUALITY
|
Всего записей: 720 | Зарегистр. 26-12-2009 | Отправлено: 12:50 02-09-2019 | Исправлено: xrun1, 05:36 05-09-2019 |
|
