Daum PotPlayer (часть 8) - [73] :: Программы :: Компьютерный форум Ru.Board

Free13man
В общем да. В каталоге профиля пользователя только лог у себя увидел. Я как то так себе набросал для удобства батник, правда только что и на быструю руку. Надеюсь ошибок нету.

Код:

@echo off
title Daum PotPlayer Install
color 4f
SetLocal EnableDelayedExpansion
:: BatchGotAdmin
:: ----------------------------------------------------------------------------------
REM - Check for permissions.
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM - If error flag set, we do not have Admin.
    if "%ErrorLevel%" NEQ "0" (
        echo Requesting Administrative privileges...
        goto UACPrompt
    ) else (
        goto gotAdmin
    )
:: ----------------------------------------------------------------------------------
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%Temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "RunAs", 1 >> "%Temp%\getadmin.vbs"
"%Temp%\getadmin.vbs"
exit /B
:: ----------------------------------------------------------------------------------
:gotAdmin
    if exist "%Temp%\getadmin.vbs" (del /f /q "%Temp%\getadmin.vbs")
CD /D "%~dp0"
color 2f
:: ----------------------------------------------------------------------------------
:EchoLine
cls
echo.
echo 1 - BackUp PotPlayer Settings;
echo 2 - Install PotPlayer and Restore Settings;
echo 3 - Restore settings;
echo 0 - Exit.
echo.
:StartLine
SET /p q=* Write the number here:
    if "%q%"=="0" (exit)
    if "%q%"=="1" (goto BackupDaum)
    if "%q%"=="2" (goto InstallDaum)
    if "%q%"=="3" (goto RestoreDaum)
    if "%q%" GEQ "04" (
        cls & echo Please enter a valid number ...
        GOTO StartLine
    )
exit /b
:BackupDaum
echo Backup PotPlayer Settings
REG QUERY "HKCU\Software\DAUM" > nul 2>&1
    if "%ERRORLEVEL%" EQU "0" (
        REG EXPORT "HKCU\Software\DAUM" "x64All.reg" /y
        timeout /t 1
    ) else (echo Registry settings not found ...)
goto EchoLine
exit /b
:InstallDaum
echo --- Start Install ---
start /wait PotPlayerSetup64.exe
start /wait OpenCodecSetup64.exe
::
echo.
    if exist "%ProgramFiles%\DAUM\PotPlayer\Skins\*.*" (copy "Skins\*.dsf" "%ProgramFiles%\DAUM\PotPlayer\Skins\*.*" )
reg delete "HKCU\Software\Daum" /f
reg import "x64All.reg"
goto EchoLine
exit /b
:RestoreDaum
echo Restore PotPlayer Settings
    if exist "x64All.reg" (
        reg delete "HKCU\Software\Daum" /f
        reg import "x64All.reg"
    )
goto EchoLine
exit /b

Модерирует : gyra, Maz
Maz (15-04-2020 13:19): Daum PotPlayer (часть 9)	Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200