VideoLAN | VLC media player (часть 2) - [840] :: Программы

Код:

@echo off
:: Для работы батника нужна утилита wget.exe. Скачать и положить в папку с батником
:: или прописать путь до WGet с обратным слэшем
set "path_to_wget="
:: Скачать
:: wget.exe - https://eternallybored.org/misc/wget/
:: версия WGet 1.21.1 - https://htmlweb.ru/download/#wget.rar
:: Путь к youtube.lua без обратного слэша
set "path_to_save=%APPDATA%\vlc\lua\playlist"

if exist "%TEMP%\youtube.lua" del /q /f "%TEMP%\youtube.lua"

%path_to_wget%wget.exe --no-check-certificate -P "%TEMP%" -N --no-hsts "https://raw.githubusercontent.com/videolan/vlc/master/share/lua/playlist/youtube.lua"

if exist "%TEMP%\youtube.lua" (
if not exist "%path_to_save%\youtube.lua" (
copy "%TEMP%\youtube.lua" "%path_to_save%"
call :result_message copied.
) else (
call :compare
)
) else (
call :result_message download error.
)
:compare
echo Comparison...
fc /c /l /w /t "%TEMP%\youtube.lua" "%path_to_save%\youtube.lua" > nul
if %errorlevel% equ 0 (
call :result_message no update required.
) else (
call :copy_
call :result_message updated.
)
exit
:copy_
if exist "%path_to_save%\youtube.lua.bak" del /q /f "%path_to_save%\youtube.lua.bak"
ren "%path_to_save%\youtube.lua" "youtube.lua.bak"
copy "%TEMP%\youtube.lua" "%path_to_save%"
exit /b
:result_message
echo.
echo ===^> youtube.lua: %*
echo.
pause
exit

Модерирует : gyra, Maz
Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению