BorlandIMHO
Silver Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Цитата:| можно ли весь код указать сразу в планировщике, без указания пути к bat файлу? |
Не то, чтобы невозможно, но я бы так делать не стал...
Цитата:
Код:| schtasks /create /sc weekly /sd 11/01/2022 /st 00:00:00 /tn "YA_disk Backup weekly" /tr "c:\Scripts\YAD_Backup.cmd" |
из командной строки 
Дату/время первого запуска (/sd и /st) подставьте желаемые, далее будет повторяться ровно через неделю.
Вместо "c:\Scripts\YAD_Backup.cmd" подставьте путь к скрипту.
YAD_Backup.cmd:
Код: @echo OFF
set "LOCAL_FOLDER_TO_BACKUP=x:\Any Path to\Folder"
set "BACKUP_LOG_FILE=y:\Any path to\logfile.txt"
call :GETTIMESTAMP TIMESTAMP
1>>"%BACKUP_LOG_FILE%" echo.
1>>"%BACKUP_LOG_FILE%" echo %TIMESTAMP:~0,4%-%TIMESTAMP:~4,2%-%TIMESTAMP:~6,2% %TIMESTAMP:~8,2%:%TIMESTAMP:~10,2%:%TIMESTAMP:~12,2% Starting backup by "%%~f0"
net use y: https://webdav.yandex.ru Your_mail_password /user:yourmail@yandex.ru /persistent:no || (1>>"%BACKUP_LOG_FILE%" echo Can't attach remote disk. Exiting. & exit)
call :GETTIMESTAMP TIMESTAMP
1>>"%BACKUP_LOG_FILE%" echo %TIMESTAMP:~0,4%-%TIMESTAMP:~4,2%-%TIMESTAMP:~6,2% %TIMESTAMP:~8,2%:%TIMESTAMP:~10,2%:%TIMESTAMP:~12,2% Atttached Backup disk to y:
set "BACKUP_FOLDER=y:\Backup_%TIMESTAMP:~0,8%"
md "%BACKUP_FOLDER%" || (1>>"%BACKUP_LOG_FILE%" echo Can't create backup folder. Exiting. & net use y: /delete & exit)
call :GETTIMESTAMP TIMESTAMP
1>>"%BACKUP_LOG_FILE%" echo %TIMESTAMP:~0,4%-%TIMESTAMP:~4,2%-%TIMESTAMP:~6,2% %TIMESTAMP:~8,2%:%TIMESTAMP:~10,2%:%TIMESTAMP:~12,2% Start copying "%LOCAL_FOLDER_TO_BACKUP%" to "%BACKUP_FOLDER%"
pushd "%LOCAL_FOLDER_TO_BACKUP%" || (1>>"%BACKUP_LOG_FILE%" echo Can't access "%LOCAL_FOLDER_TO_BACKUP%". Exiting. & popd & net use y: /delete & exit)
xcopy * "%BACKUP_FOLDER%" /E /Y /Z /V /J || (1>>"%BACKUP_LOG_FILE%" echo Errors at copying. Exiting. & popd & net use y: /delete & exit)
call :GETTIMESTAMP TIMESTAMP
1>>"%BACKUP_LOG_FILE%" echo %TIMESTAMP:~0,4%-%TIMESTAMP:~4,2%-%TIMESTAMP:~6,2% %TIMESTAMP:~8,2%:%TIMESTAMP:~10,2%:%TIMESTAMP:~12,2% Succesfully copyed "%LOCAL_FOLDER_TO_BACKUP%" to "%BACKUP_FOLDER%. Exiting."
popd
net use y: /delete
goto :EOF
:GETTIMESTAMP
for /f "usebackq tokens=2 delims==" %%A in (`wmic os get LocalDateTime /value`) do set "%~1=%%A"
goto :EOF |
Логины/пароли, путь к копируемой папке и путь к лог-файлу подставить свои.
|
Всего записей: 2403 | Зарегистр. 12-10-2006 | Отправлено: 22:48 10-01-2022 | Исправлено: BorlandIMHO, 22:59 10-01-2022 |
|
) и выполняем. Вывод либо копируем, либо по правой кнопке сохраняем в файл, потом в файле удаляем лишнее. 
