Корпоративные продукты McAfee / Networks Associates (NAI) - [74] :: В помощь системному администратору

Rosiyanka
Вопрос с перепаковкой я решил, проблема была в том что в репозитории самого ePO (Master Repository) лежала старая сборка. сделал следующим образом положил все службы МкАфее удалил FramePkg.exe и Framework.z из папки репозитория (ручками с помощью проводника, а не через веб-консоль). Запустил службы они создали новые сборки.

SergIRBIS
Вот скрипт CMAInstall.wsf:

<job id="Install McAfee Common Management Agent">

<script language="VBScript">
    Option Explicit
    On Error Resume Next

'------------------- E-MAIL Settings ----------------------------
Const MailRecipient = "admin_emails@domain.com"
Const SMTPServer = "mail.domain.com"
'--------------------------------------------------------------------

    Dim wshShell, objWMIService, colItems, objItem, objNetwork, objMessage
    Dim CMAExists, CMARunning
    Dim SendMail, MailBody

    'init variables
    CMAExists = False
    CMARunning = False
    SendMail = False
    MailBody = ""
    Set wshShell = CreateObject("WScript.Shell")
    Set objNetwork = CreateObject("WScript.Network")
    Set objMessage = CreateObject("CDO.Message")

    ' CMA exists???
    Set objWMIService = GetObject("winmgmts:\\.\root\CIMV2")
    Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Service",,48)
    For Each objItem In colItems
        If objItem.Name = "McAfeeFramework" Then
            If CStr(objItem.State) = "Running" Then
                CMARunning = True
            End If
            CMAExists = True
            Exit For
        End If
    Next

    If Not CMAExists Then
        wshShell.Run "FramePkg.exe /Install=Agent /ForceInstall /Silent",0,False
        MailBody = MailBody + "- CMA service don't exists. Start CMA install." + vbCrLf
        SendMail = True
    Else
        If Not CMARunning Then
            MailBody = MailBody + "CMA service exists, but not running!"
            SendMail = True
        End If
    End If


    If SendMail Then
        'initialize mail
        objMessage.From = objNetwork.ComputerName + "<McAfee@domain.com>"
        objMessage.To = MailRecipient
        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=2
        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTPServer
        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate")=0
        objMessage.Configuration.Fields.Update

        objMessage.Subject = "CMA - " + objNetwork.ComputerName
        objMessage.TextBody = MailBody
        objMessage.Send
    End If
</script>
</job>

Скрипт делает простые вещи:
- проверят есть ли среди служб служба с названием "McAfeeFramework" и находится ли она в состоянии "Запушена";
- если службы нет - запускается инсталяция агента (FramePkg.exe с параметрами)
- если запущена инсталяция или служба не работает (остановлена или задисейблена), то отправляется отчет по электронной почте руководствуясь параметрами указанными в начале скрипта.

FramePkg.exe должен лежать в той же папке, что и скрипт. Я кладу оба в папку объекта групповой политик предназначенную лдя скриптов.

Модерирует : lynx, Crash_Master, dg, emx, ShriEkeR
emx (17-04-2009 09:27): Корпоративные продукты McAfee / Networks Associates (NAI) II	Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102