Порты для почтового сервера - [2] :: В помощь системному администратору

Когда-то писал для себя батник для сабжа средствами srvany и intsrv.

Код:

@echo off

if not "%OS%"=="Windows_NT" goto exit
if not exist %windir%\system32\instsrv.exe (
if exist instsrv.exe (
copy instsrv.exe %windir%\system32\ >nul
if not exist %windir%\system32\srvany.exe (
if exist srvany.exe (
copy srvany.exe %windir%\system32\ >nul
) else (
echo.
echo Ошибка! Файл srvany.exe не найден.
goto exit
)
)
) else (
echo.
echo Ошибка! Файл instsrv.exe не найден.
goto exit
)
)
if "%1"=="" (
echo.
echo Ошибка! Не указан исполняемый файл в параметрах.
goto exit
)
if /i not "%~x1"==".exe" (
if /i not "%~x1"==".bat" (
if /i not "%~x1"==".cmd" (
echo.
echo Ошибка! Файл "%~nx1" не является исполняемым.
echo В параметрах должен быть указан только .exe ^|.bat ^|.cmd файл.
goto exit
)
)
)
if /i "%~f1"=="%~f0" goto exit

echo Путь к файлу в качестве службы: %~f1
echo.
set /p svcname="Имя устанавливаемой службы: "
if "%svcname%"=="" (
echo.
echo Ошибка! Не указано имя устанавливаемой службы.
goto exit
)
echo.
set /p yesno="Файл "%1" будет установлен в качестве службы "%svcname%". [y/n]: "
if /i not "%yesno%"=="y" goto exit

%windir%\system32\instsrv.exe %svcname% %windir%\system32\srvany.exe

if exist %svcname%.vbs del /q %svcname%.vbs

echo Dim WshShell >%svcname%.vbs
echo Set WshShell = WScript.CreateObject("WScript.Shell") >>%svcname%.vbs
echo Const root = "HKEY_LOCAL_MACHINE" >>%svcname%.vbs
echo Const key = "\SYSTEM\CurrentControlSet\Services\" >>%svcname%.vbs
echo WshShell.RegWrite root ^& key ^& "%svcname%" ^& "\Parameters\Application", "%~f1", "REG_SZ" >>%svcname%.vbs

cscript %svcname%.vbs //nologo
del /q %svcname%.vbs

echo.
set /p yesno="Запустить установленную службу "%svcname%"? [y/n]: "
if /i not "%yesno%"=="y" goto exit
echo.
net start %svcname%

:exit
echo.
echo Нажмите любую клавишу для выхода...
pause >nul

Ну и батник для удаления сервиса тоже:

Код:

@echo off

if not "%OS%"=="Windows_NT" goto exit
if not exist %windir%\system32\instsrv.exe (
if exist instsrv.exe (
copy instsrv.exe %windir%\system32\ >nul
) else (
echo.
echo Ошибка! Файл instsrv.exe не найден.
goto exit
)
)

set /p svcname="Имя удаляемой службы: "
if "%svcname%"=="" (
echo.
echo Ошибка! Не указано имя удаляемой службы.
goto exit
)
echo.
set /p yesno="Служба "%svcname%" будет удалена. [y/n]: "
if /i not "%yesno%"=="y" goto exit
echo.

net stop %svcname%

%windir%\system32\instsrv.exe %svcname% REMOVE

:exit
echo.
echo Нажмите любую клавишу для выхода...
pause >nul

Добавлено:

Цитата:

Народ а где взять эти srvany и insrsv

В Resource Kit от win 2003 например.

Модерирует : lynx, Crash_Master, dg, emx, ShriEkeR
Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3