Динамический IP - Dynamic IP - на Email - [2] :: В помощь системному администратору

ober83
ваш батник:
1. Стартует приложение Pico2000
2. Засыпает на 10 секунд
3. Пишет даные об IP в лог - с добавлением последних данных с существующий файл.
4. Шлёт этот лог файл на почту
5. Засыпает на 6 часов
6. перегружает PC

Проверил вот такой батник:
1. Стартуем приложение
2. Засыпаем на 10 секунд
3. Смотрим текущее время
4. Смотрим текущий IP и пишем в общий лог - LOGIP=C:\ip-log.txt
5. Смотрим текущий IP и пишем его в лог с текущим IP - CURRENTIP=C:\ip-current.log
6. Сравниваем лог с текущим IP и лог с предыдущим IP - PRECEDENTIP=C:\ip-precedent.log, если есть различия, то шлём почту - иначе п7.
7. Засыпаем на 6 часов.
8. Перегружаем PC.

При самом первом запуске PRECEDENTIP=C:\ip-precedent.log - отсутсвует, т.о. при первом запуске будет выслано уведомление на почту, а далее уже только при изменении.
Особое внимание обратите на переменную:

Цитата:

SET IPADDRESSTEMPALTE="IPv4 Address"

У вас в примере это "IP-адрес".

Работоспособность проверенна на Windows 7 Ultimate x64.

Код:

::
:: Send Changed IP via Email
::
::
start Pico2000
sleep 10
::
for /f "tokens=1-3 delims=:,./- " %%I in ("%TIME%") do set "Time-hour=%%I" & set "Time-min=%%J" & set "Time-sec=%%K"
if %Time-hour% LSS 10 set Time-hour=0%Time-hour%
set Time=%Time-hour%-%Time-min%-%Time-sec%
for /f "tokens=2-4 delims=:,./- " %%I in ("%DATE%") do set Date=%%K-%%I-%%J
set Now=%Date%--%Time%
::
::
SET IPADDRESSTEMPALTE="IPv4 Address"
SET LOGIP=C:\ip-log.txt
SET CURRENTIP=C:\ip-current.log
SET PRECEDENTIP=C:\ip-precedent.log
::
SET MAILDIR=c:\full
SET MAILSERVER=smtp.mail.ru
SET MAILTO=user@mail.ru
SET MAILFROM=user@mail.ru
SET MAILUSER=user@mail.ru
SET MAILPASSWORD=*******
SET MAILSUBJECT="IP-Changes-Report - %Now%"
SET MAILBODY=%CURRENTIP%
::
::
::
::
ECHO %Now% >>%LOGIP%
ipconfig | FIND %IPADDRESSTEMPALTE% >> %LOGIP%
ECHO ------------------------------ >>%LOGIP%
ipconfig | FIND %IPADDRESSTEMPALTE% >%CURRENTIP%
::
ECHO n | comp %CURRENTIP% %PRECEDENTIP% /L /D
IF %ERRORLEVEL% EQU 0 GOTO exit
::
:sendipviaemail
%maildir%\blat.exe -server %MAILSERVER% -u %MAILUSER% -pw %MAILPASSWORD% -f %MAILFROM% -to %MAILTO% -subject %MAILSUBJECT% -bodyF %MAILBODY%
copy %CURRENTIP% %PRECEDENTIP%
::
:exit
sleep 21600
shutdown -r -t 0

Модерирует : lynx, Crash_Master, dg, emx, ShriEkeR
Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3