BorlandIMHO
Silver Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Цитата: Начинаю слать пинг на сервер, ping x.x.x.x -l 50000 -w 1 -n 100 (типа 50000 байт в секунду)
как сделать так, чтобы когда приходит "request timed out", то в файл log.txt об этом писалось
"<date><time> пинг не прошел(" |
Решал сходную задачу:
Packet_Loss_Catcher.cmd
Код: REM Адрес пингуемого узла
SET PINGADDR=192.168.1.1
REM Размер пакета для пинга
SET PACKETSIZE=32
REM Количество пакетов
SET ITERATIONS=86400
REM Временной промежуток между пакетами в секундах +1, т.е. для промежутка в 1 секунду д.б. 2
SET ITERLENGTH=2
echo Pinging %PINGADDR% by %PACKETSIZE%-bytes packets>Packet_Loss_Catcher%PACKETSIZE%.log
echo Started at %DATE% %TIME%.>>Packet_Loss_Catcher%PACKETSIZE%.log
echo.>>Packet_Loss_Catcher%PACKETSIZE%.log
for /l %%I in (1,1,%ITERATIONS%) do (
ping -n 1 -l %PACKETSIZE% %PINGADDR%
IF ERRORLEVEL 1 CALL :TIMER
ping -n %ITERLENGTH% 127.0.0.1>nul
)
echo.>>Packet_Loss_Catcher%PACKETSIZE%.log
CALL :FINISHER
rar m -m5 -md64 -- PLC%PACKETSIZE%_LOG_%DATE:~9,4%%DATE:~6,2%%DATE:~3,2%_%TIME:~0,2%%TIME:~3,2%%TIME:~6,2% Packet_Loss_Catcher%PACKETSIZE%.log
START %~nx0
exit
:TIMER
echo Packet loss at: %DATE% %TIME:~0,8%>>Packet_Loss_Catcher%PACKETSIZE%.log
GOTO :EOF
:FINISHER
echo.>>Packet_Loss_Catcher%PACKETSIZE%.log
echo Ended at %DATE% %TIME%.>>Packet_Loss_Catcher%PACKETSIZE%.log
GOTO :EOF
|
Этот скрипт висел на сервере, постоянно пинговал удалённый сервер одиночными пакетами (размер пакета и др. параметры задаются в начале). При потере пакета в лог пишется "Packet loss at: %DATE% %TIME:~0,8%" (дата и время с точностью до секунды) Отработав заданное количество итераций паковал лог в архив и перезапускался (с текущими параметрами цикл выполнения скрипта чуть больше суток)
|
Всего записей: 2403 | Зарегистр. 12-10-2006 | Отправлено: 17:57 23-10-2009 | Исправлено: BorlandIMHO, 17:59 23-10-2009 |
|
