Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)

Модерирует : gyra, Maz

articlebot (21-06-2016 11:40): Следующая часть - Командная строка, батники, сценарии (bat, cmd)  Версия для печати • ПодписатьсяДобавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452

   

Widok



Moderator-Следопыт
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Командная строка, батники\сценарии (bat, cmd)
(часть 1) (часть 2) (часть 3)
Вопросы, задачи и их решения по работе с командной строкой, файлами, а также сопутствующие ссылки.

 
Важно: копируя батник через буфер обмена из форума не забывайте удалять пробелы в конце каждой строки, т.к. в некоторых случаях из-за этого программа будет работать неправильно!!! Чтобы не копировались концевые пробелы из форума, жмите на ссылку "Редактировать" в посте, и уже из редактора копируйте батник без пробелов.
 
Примечание: Большие куски кода заключайте в тэг [more]  
 
Смежные темы:
В помощь системному администратору » Автоматизация администрирования
Microsoft Windows » Задачи на bat-файлах 12
 
Полезные ссылки
· Из Windows XP Professional Product Documentation:
» Описание Cmd.exe » Command shell overview
» Using batch files » Using batch parameters » Using filters » Using command redirection operators
 
· Уроки bat-аники (для начинающих): первый и второй
· Курс из 19 лекций "Командная строка и сценарии Windows"
· Попов А. Командная строка и сценарии Windows (PDF). Курс лекций для начинающих
· Бокалий В. Командная строка (pdf-брошюрка в 20 страниц)
· Александров А., Дибров А. Урок bat-аники (pdf)
· Уильям Р. Станек - Командная строка Windows. Справочник администратора
 
· Скрываем консольные окна
· cmdow — изменение параметров и видимости дос-окна, Статья в КОМПЬЮТЕРРАONLINE
· Набор GNU утилит для win32
· HS_Packet.zip - Пакет утилит для организации интерфейса в bat-файлах
· Использование ansi.sys
· blat — отправка почты из консоли
· Команды RunDll32
· Quick Batch File Compiler - Позволяет превратить ваш батник в независимое приложение
· Easy Batch Builder+Rus+Crack - Редактор BAT файлов.Через графический интерфейс программы вы сможете быстро конструировать пакетные файлы практически любой сложности. (В комплекте есть Лоадер созданный с помощью Sign Of Misery некоторые антивирусы обзывают его вирусом. Вам решать: ставить или не ставить) (ЗЕРКАЛО)
 
· Простой способ получать текущую дату всегда в одном формате (не зависит от языков и настроек) ещё и ещё
· Переход из 32-битной версии cmd.exe в 64-битную (1) (2)

Всего записей: 24190 | Зарегистр. 07-04-2002 | Отправлено: 16:29 03-03-2010 | Исправлено: regist123, 13:32 02-11-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
YuS_2
Скобки - это тоже частный случай. Дело в единстве строки:

Код:
 
for %%A in (1) do (
  set A=1
  echo %A%
)
 
for %%A in (1) do set B=1 & echo %B%
 
for %%A in (1) do set C=1^
 & echo %C%
 

Все три примера вернут "ECHO is off."
 

Цитата:
Где-то была хорошая статья по батникам

"Уроки batаники" в шапке.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 17:57 17-05-2015
YuS_2



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin

Цитата:
Скобки - это тоже частный случай.

Действительно... век живи -век учись, как говорится.
 

Цитата:
"Уроки batаники" в шапке.

Точно, оно самое.

Всего записей: 3218 | Зарегистр. 03-02-2009 | Отправлено: 18:16 17-05-2015
brRamires

Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Если запустить следующий скрипт

Код:
 
@echo off
 
call :MY_PROCEDURE "C:\Program Files"
call :MY_PROCEDURE "C:\Program Files (x86)"
pause
exit /B
 
:MY_PROCEDURE
    if 1==1 echo %~f1
    if 1==1 (
        echo %~f1
    )
    exit /B
 

- то получим

Код:
 
C:\Program Files
C:\Program Files
C:\Program Files (x86)
C:\Program Files (x86
Для продолжения нажмите любую клавишу . . .
 

Спрашивается, куда делась скобка и как с этим бороться?

Всего записей: 564 | Зарегистр. 28-09-2008 | Отправлено: 22:38 17-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
brRamires
Куда делась - понятно: закрыла открытую скобку. Бороться использованием delayed expansion:

Код:
@echo off
 
call :MY_PROCEDURE "C:\Program Files"
call :MY_PROCEDURE "C:\Program Files (x86)"
pause
exit /B
 
:MY_PROCEDURE
    set f1=%~f1
    setlocal enabledelayedexpansion
    if 1==1 echo !f1!
    if 1==1 (
        echo !f1!
    )
    exit /B
 


----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 22:49 17-05-2015
brRamires

Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
Получается, присваивания типа "set f1=%~f1" опасно делать внутри скобок, т.к. программист не защищён от наличия скобки в передаваемых параметрах. Остаётся лишь вариант set f1="%~f1"& set f1=!f1:"=!

Всего записей: 564 | Зарегистр. 28-09-2008 | Отправлено: 23:18 17-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
brRamires
Не только присваивания, а вообще использование %-переменных, которые могут содержать символы: &|<>). В таких случаях нужно обязательно присваивать "подозрительное" значение новой переменной и в дальнейшем обращаться к ней только через delayed expansion.
 

Цитата:
Остаётся лишь вариант set f1="%~f1"& set f1=!f1:"=!

set "f1=%~f1"
 
Добавлено:
brRamires

Цитата:
set f1="%~f1"& set f1=!f1:"=!

Это, кстати, вообще некорректно. Выполните

Код:
 
test.cmd "1""2"
 

test.cmd:

Код:
 
@echo off
echo %1
setlocal enabledelayedexpansion
set f1="%~1"& set f1=!f1:"=!
echo !f1!
 

 
Добавлено:
Я бы даже сказал, дважды некорректно: setlocal enabledelayedexpansion д. б. вставлено между set'ами.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 23:33 17-05-2015 | Исправлено: GCRaistlin, 23:42 17-05-2015
brRamires

Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin

Цитата:
set "f1=%~f1"

Спасибо, это как раз то, что нужно.
 

Цитата:
test.cmd "1""2"

Это понятно, я имел ввиду только работу с именами файлов, где кавычки недопустимы.
 

Цитата:
setlocal enabledelayedexpansion д. б. вставлено между set'ами.

У меня первой строкой всегда идёт @echo off & setlocal EnableExtensions EnableDelayedExpansion - так универсальней. Не вижу, какие преимущества дают переменные типа %MyVar% над !MyVar!. Первые использую только если нужно сделать set MyStr=!MyStr:%MySubstr%=!

Всего записей: 564 | Зарегистр. 28-09-2008 | Отправлено: 00:18 18-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
brRamires

Цитата:
У меня первой строкой всегда идёт @echo off & setlocal EnableExtensions EnableDelayedExpansion - так универсальней.

test.cmd:

Код:
 
@echo off
setlocal enabledelayedexpansion
set "A=%~1"
echo !A!
 


Код:
 
test.cmd Yes!
 


----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 00:27 18-05-2015
brRamires

Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
А если нужно многократно модифицировать переменную, и без enabledelayedexpansion не обойтись? Существует ли решение проблемы пропадания восклицательных знаков?

Всего записей: 564 | Зарегистр. 28-09-2008 | Отправлено: 01:10 18-05-2015
korosya

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin

Цитата:
Вставьте между c и g запятую вместо пробела и попробуйте снова. Или после cg - две кавычки вместо одной, тоже результат интересный получится.

Да, тут вы правы. Насчет нечетного количества кавычек в подстроке - у меня такого не должно быть, так что не буду заострять на этом внимания. А вот насчет запятой - нет ли каких-нибудь мыслей?

Всего записей: 1005 | Зарегистр. 19-07-2003 | Отправлено: 09:20 18-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
korosya
Запятая, точка с запятой, табуляция - такие же полноправные разделители, как и пробел. Соответственно, их тоже нужно временно заменять. Обратите внимание еще на один момент: если <str> содержит окавыченные

Код:
&|<>)

, ваша команда FOR вылетит. Нужно опять же использовать delayed expansion для str'ов.
 
brRamires
Не пропадания. Для указанного test.cmd выполните

Код:
test.cmd !windir!

Для многократной модификации вовсе не обязательно постоянно держать включенным delayed expansion. Более того, оно вам не позволит сделать замену подстроки, содержащей "!", и вызовет ошибки при использовании FOR, если FOR-переменные содержат "!".

Код:
 
@echo off
set A=foobar
set B=bar
setlocal enabledelayedexpansion
for /f "delims=" %%A in ("!A:%B%=!") do (
  endlocal
  set A=%%A
)
echo %A%
 
set A=foo!bar!
set B=!bar!
call set A=%%A:%B%=%%
echo %A%
 

Несмотря на лаконичность второго варианта, это - тормозной костыль, который может использоваться не со всеми командами (в частности, не будет работать с FOR и IF), поэтому прибегать к его использованию стоит только тогда, когда без него не обойтись.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 15:08 18-05-2015
brRamires

Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
Кажется, что-то начинаю понимать, а именно: конструкции вида %MyVar%, как и !MyVar! разрешаются в момент выполнения команды, но разница в том, что, в первом случае всё, что внутри скобок, а также при использовании "&" воспринимается как одна команда, а во втором - как множество команд. Поэтому скрипт

Код:
 
@echo off
echo enabledelayedexpansion=off
 
set B=0
(
    set B=1
    echo in "()" B=%B%
)
echo after "()" B=%B%
 
set B=0
if 10==10 (
    set B=10
    echo in "if" B=%B%
)
echo after "if" B=%B%
 
set B=0
for %%A in (100 200 300) do (
    set B=%%A
    echo in "for" B=%B%
)
echo after "for" B=%B%
 
set B=0
set B=1000& echo in "&" B=%B%
echo after "&" B=%B%
 
setlocal enabledelayedexpansion
echo enabledelayedexpansion=on
 
set B=0
(
    set B=1
    echo in "()" B=!B!
)
echo after "()" B=!B!
 
set B=0
if 10==10 (
    set B=10
    echo in "if" B=!B!
)
echo after "if" B=!B!
 
set B=0
for %%A in (100 200 300) do (
    set B=%%A
    echo in "for" B=!B!
)
echo after "for" B=!B!
 
set B=0
set B=1000& echo in "&" B=!B!
echo after "&" B=!B!
 

выдаёт такой результат

Код:
 
enabledelayedexpansion=off
in "()" B=0
after "()" B=1
in "if" B=0
after "if" B=10
in "for" B=0
in "for" B=0
in "for" B=0
after "for" B=300
in "&" B=0
after "&" B=1000
enabledelayedexpansion=on
in "()" B=1
after "()" B=1
in "if" B=10
after "if" B=10
in "for" B=100
in "for" B=200
in "for" B=300
after "for" B=300
in "&" B=1000
after "&" B=1000
 

Раньше мне казалось, что переменные вида %MyVar% вообще действуют как константы.
 

Цитата:
 
@echo off  
setlocal enabledelayedexpansion  
set "A=%~1"  
echo !A!  
 
Код:
test.cmd Yes!
test.cmd !windir!
 

Во втором случае понятно, что set "A=%~1" сразу разрешается в set "A=!windir!", а значит set "A=C:\Windows". А что происходит в первом случае?

Всего записей: 564 | Зарегистр. 28-09-2008 | Отправлено: 01:58 19-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
brRamires

Цитата:
конструкции вида %MyVar%, как и !MyVar! разрешаются в момент выполнения команды

Нет. %MyVar% разрешается в момент чтения строки.

Цитата:
в первом случае всё, что внутри скобок, а также при использовании "&" воспринимается как одна команда, а во втором - как множество команд

И в том, и в другом случае - как одна строка.

Цитата:
Во втором случае понятно, что set "A=%~1" сразу разрешается в set "A=!windir!", а значит set "A=C:\Windows". А что происходит в первом случае?

А в первом случае разрешается в !Yes!!. Переменная Yes не определена, соответственно, получается пустая строка. Лишний '!' просто отбрасывается.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 09:11 19-05-2015
Pasha_ZZZ



Platinum Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
korosya
GCRaistlin
Цитата:
Запятая, точка с запятой, табуляция - такие же полноправные разделители, как и пробел
Этого можно избежать, если явно указать нужные разделители в delims=

Всего записей: 12375 | Зарегистр. 11-03-2002 | Отправлено: 09:22 19-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Pasha_ZZZ
В варианте использования FOR, который указан в исходном посте, этого избежать нельзя.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 12:01 19-05-2015
Pasha_ZZZ



Platinum Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
GCRaistlin
Там вообще, с учетом наличия именно "любых" символов, не рекомендована обработка в батнике.

Всего записей: 12375 | Зарегистр. 11-03-2002 | Отправлено: 13:54 19-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Pasha_ZZZ
Раз кавычек внутри <str> может быть только четное количество, как впоследствии уточнил автор, я проблем с обработкой в батнике не вижу.

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 13:57 19-05-2015
korosya

Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin

Цитата:
Запятая, точка с запятой, табуляция - такие же полноправные разделители, как и пробел. Соответственно, их тоже нужно временно заменять.

Вот с этим-то получается проблемка - запятая одновременно является и разделителем и может находится в подстроках. Например, как вы правильно указали на возможную подстроку типа:

Код:
a,b,"c,g"de""

Как обработать такую подстроку?
насчет символов &|<>) - думаю проблем не будет, если их также, как и пробелы, заменять пред обработкой.

Всего записей: 1005 | Зарегистр. 19-07-2003 | Отправлено: 14:36 19-05-2015
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
korosya
Что мешает поступить с запятой так же, как с пробелом?
 

Цитата:
насчет символов &|<>) - думаю проблем не будет, если их также, как и пробелы, заменять пред обработкой

Зачем, если можно использовать delayed expansion?

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 14:44 19-05-2015
brRamires

Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin, Спасибо за разъяснения.

Всего записей: 564 | Зарегистр. 28-09-2008 | Отправлено: 16:00 19-05-2015
   

Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)
articlebot (21-06-2016 11:40): Следующая часть - Командная строка, батники, сценарии (bat, cmd)


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru