Командная строка, батники, сценарии (bat, cmd) - [8337] :: Программы

Код:

@echo off
set "param=%~1"
reg query "HKLM\system\RNG" && (
if not defined param if exist "%TEMP%\param.txt" (set /p param=<"%TEMP%\param.txt" & del /q "%TEMP%\param.txt")
) || goto :UACPrompt
set "key=HKEY_CLASSES_ROOT\chm.file\shell\open\command"

if /I "%param%"=="/restore" (
set "cmd=reg add "%key%" /ve /t REG_EXPAND_SZ /d "\"%%windir%%\hh.exe\" %%1" /f"
call :write & goto :eof
)
if exist "%param%" (
set "cmd=reg add "%key%" /ve /d "\"%param%\" %%1" /f"
call :write & goto :eof
)
:: только первый ехе-шник по списку
for /f "delims=" %%A in ('dir "%~dp0*.exe" /B /O-D') do (
set "cmd=reg add "%key%" /ve /d "\"%~dp0%%~A\" %%1" /f"
call :write & goto :eof
)
goto :eof

:write
%cmd%
if %ErrorLevel% NEQ 0 (
call :takePermReg
%cmd%
)
goto :eof
:takePermReg
:: Получение имени группы "Администраторы". Проверка на англ. язык
set "admin_group=Администраторы"
1>nul 2>&1 net localgroup %admin_group%
if %ErrorLevel% EQU 0 goto :takePermReg_next
set "admin_group=Administrators"
1>nul 2>&1 net localgroup %admin_group%
if %ErrorLevel% EQU 0 goto :takePermReg_next
echo error. Suitable groups not exist
net localgroup
pause & goto :eof
:takePermReg_next
set "subinacl=%Soft%\#CMD tools\_ACLS\subinacl\subinacl.exe"
call "%subinacl%" /subkeyreg "%key%" /setowner=%admin_group%
call "%subinacl%" /subkeyreg "%key%" /grant=%admin_group%=F
call "%subinacl%" /subkeyreg "%key%" "/setowner=NT SERVICE\TrustedInstaller"
goto :eof

:UACPrompt
chcp 1251
>"%TEMP%\getadmin.vbs" echo Set UAC = CreateObject^("Shell.Application"^)
>>"%TEMP%\getadmin.vbs" echo UAC.ShellExecute "%~f0", "", "", "runas", 1
>"%TEMP%\param.txt" echo.%param%
start /b %TEMP%\getadmin.vbs & exit

Модерирует : gyra, Maz
articlebot (21-06-2016 11:40): Следующая часть - Командная строка, батники, сценарии (bat, cmd)	Версия для печати • Подписаться • Добавить в закладки
На первую страницу • к этому сообщению • к последнему сообщению