YuS_two
Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Код: @echo off
echo Сценарий упаковки файла динамического виртуального диска Oracle VirtualBox.
echo Перед упаковкой, необходимо в загруженной гостевой ОС выполнить максимальную
echo дефрагментацию, затем заполнить нулями свободное пространство ^(для этого
echo хорошо подходит программа sDelete ^(sysinternals.com^)^).
echo Примечание: Имя упаковываемого, неподключенного файла виртуального диска НЕ
echo должно совпадать с любым подключенным файлом, либо абсолютный путь в сценарии
echo должен быть указан только от реально подключенного виртуального диска.
echo.
choice /c yn /m "Продолжаем "
if "%errorlevel%"=="1" goto begin
echo.
echo Выходим
echo.
pause&&exit
:begin
cls
echo Выполните следующие действия:
echo.
pushd "%~dp0"
set /p x="Укажите абсолютный путь к каталогу с виртуальным диском (q=выход): "
if "%x%"=="q" (echo Выходим&&pause&&exit)
if not exist "%x%\*.vdi" (echo.&&echo В этом каталоге нет файлов виртуальных дисков&&pause&&goto begin)
cd /d "%x%"
echo.
echo Найдены файлы виртуального диска:
echo.
setlocal enabledelayedexpansion
set cnt=0
for /f "delims=" %%a in ('dir /a-d/b *.vdi') do (
call :per "%%~a"
)
goto file
:per
set /a cnt+=1
set var%cnt%=%~1
echo %cnt%. !var%cnt%!
exit /b
:file
echo.
set /p y="Введите номер файла виртуального диска: "
if not defined var%y% (echo.&&echo Нет такого файла&&goto chce) else (goto pusk)
pause&&exit
:chce
choice /c yn /m "Выходим "
goto answ%errorlevel%
echo Ошибка. Выходим
pause&&exit
:answ1
echo Выход
timeout /t 3
exit
:answ2
goto file
:pusk
echo.
echo Запускаем упаковку:
echo.
rem Путь к файлу vboxmanage.exe должен быть прописан в системной переменной Path,
rem либо для корректного запуска необходимо указать абсолютный путь:
vboxmanage modifyhd "!var%y%!" --compact
if errorlevel 1 (
endlocal
echo.
echo.
echo. Ошибка!!! Имя файла виртуального диска совпадает с именем
echo. подключенного файла, при отличающихся абсолютных путях
echo.
echo.
)
endlocal
echo.
pause |
|
Всего записей: 399 | Зарегистр. 28-03-2016 | Отправлено: 18:05 30-05-2016 | Исправлено: YuS_two, 22:40 03-06-2016 |
|
