Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)

Модерирует : gyra, Maz

Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6  Версия для печати • ПодписатьсяДобавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199

   

cchameleone



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Командная строка, батники\сценарии (bat, cmd)
(часть 1) (часть 2) (часть 3) (часть 4)
Вопросы, задачи и их решения по работе с командной строкой, файлами, а также сопутствующие ссылки.

Важно: копируя батник через буфер обмена из форума не забывайте удалять пробелы в конце каждой строки, т.к. в некоторых случаях из-за этого программа будет работать неправильно!!! Чтобы не копировались концевые пробелы из форума, жмите на ссылку "Редактировать" в посте, и уже из редактора копируйте батник без пробелов.
 
Примечание: Большие куски кода заключайте в тэг [ more ].  

Смежные темы:
В помощь системному администратору » Автоматизация администрирования
Microsoft Windows » Сценарии Windows

Полезные ссылки:
· Из Windows XP Professional Product Documentation:
» Описание Cmd.exe » Command shell overview
» Using batch files » Using batch parameters » Using filters » Using command redirection operators
 
· Уроки bat-аники (для начинающих): первый и второй
· Курс из 19 лекций "Командная строка и сценарии Windows"
· Попов А. Командная строка и сценарии Windows (PDF). Курс лекций для начинающих
· Бокалий В. Командная строка (pdf-брошюрка в 20 страниц)
· Александров А., Дибров А. Урок bat-аники (pdf)
· Уильям Р. Станек - Командная строка Windows. Справочник администратора
 
· Скрываем консольные окна, Выполнение BAT-скриптов без вызова окна консоли
· cmdow — изменение параметров и видимости дос-окна, Статья в КОМПЬЮТЕРРАONLINE
· Набор GNU утилит для win32
· HS_Packet.7z - Пакет утилит для организации интерфейса в bat-файлах
· Использование ansi.sys
· blat — отправка почты из консоли
· Команды RunDll32
· Quick Batch File Compiler - Позволяет превратить ваш батник в независимое приложение
· Easy Batch Builder+Rus+Crack - Редактор BAT файлов.Через графический интерфейс программы вы сможете быстро конструировать пакетные файлы практически любой сложности. (В комплекте есть Лоадер созданный с помощью Sign Of Misery некоторые антивирусы обзывают его вирусом. Вам решать: ставить или не ставить) (ЗЕРКАЛО)
· Простой способ получать текущую дату всегда в одном формате (не зависит от языков и настроек) ещё и ещё
· Переход из 32-битной версии cmd.exe в 64-битную (1) (2)(3)

Всего записей: 2279 | Зарегистр. 16-10-2015 | Отправлено: 09:22 29-04-2016 | Исправлено: Maz, 08:47 26-03-2020
Alex_Piggy

Advanced Member
Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
Доброе время, Expert LTD
?

Код:
 
@echo off
:rs
Echo Выбор пользователя:
Echo.
Echo 1 - User1
Echo 2 - User3
Echo 3 - User2
echo.
Set /p user="Выбранный пользователь: "
set user=%user%
set "USERDATA="
if "%user%"=="1" set "USERDATA=user1"
if "%user%"=="2" set "USERDATA=user2"
if "%user%"=="3" set "USERDATA=user3"
if "%user%"=="4" set "USERDATA=user4"
if not defined userdata (echo JError & goto :rs) else (goto :rsok)
:rsok
query session /server:%USERDATA%
set /P rid="Выбрать сессии: "
start mstsc /shadow:%rid% /v:%USERDATA% /control
 

 
Добавлено:
v2

Код:
@echo off
setlocal enabledelayedexpansion
set "count=0"
for /i in (user1 user2 user3 user4) do (
  set /a "count=count+1"
  call set "user!count!=%%i"
  echo !count! - %%i
)
Set /p user="Выбранный пользователь: "  
set "userdata="
call set "userdata=%%user%user%%%"
if not defined userdata (echo JError & goto :rs) else (goto :rsok)
:rsok
query session /server:%USERDATA%
set /P rid="Выбрать сессии: "
start mstsc /shadow:%rid% /v:%USERDATA% /control  

Всего записей: 1883 | Зарегистр. 07-08-2002 | Отправлено: 11:49 28-05-2020
Expert LTD



Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Alex_Piggy
Благодарю!

Всего записей: 46 | Зарегистр. 20-05-2008 | Отправлено: 07:45 29-05-2020
Artem_Butenko



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Ребята, пожалуйста подскажите, каким образом в пакетном файле узнать тип носителя с которого он запущен и, если это не Removable диск, завершить исполнение сценария. Заранее благодарен за конструктивный совет!

Всего записей: 707 | Зарегистр. 19-02-2008 | Отправлено: 15:07 29-05-2020
Fenrizz



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Artem_Butenko
 
FOR /F "usebackq skip=1 tokens=1,2,3" %%a IN (`"wmic logicaldisk where caption='%~d0' get drivetype"`) DO (  
IF "%%a"=="2" (
ECHO 1234567890 ) )

Всего записей: 677 | Зарегистр. 12-09-2017 | Отправлено: 15:40 29-05-2020 | Исправлено: Fenrizz, 16:15 29-05-2020
RetroRocket



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Artem_Butenko
Цитата:
если это не Removable диск, завершить исполнение сценария.
Примерно так можно:
Код:
@wmic logicaldisk get name,drivetype | find "2" | find /i "%~d0">nul
@if errorlevel 1 echo Error: starting from a fixed drive is not allowed. Press any key to exit.&&pause>nul&&exit /b 1
 
@echo Starting from a removable drive is allowed. Press any key to continue.&&pause>nul
 


----------
"... Зовёт, зовёт в дорогу далёкий Млечный Путь ..."

Всего записей: 2682 | Зарегистр. 02-01-2018 | Отправлено: 16:12 29-05-2020
Artem_Butenko



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Fenrizz
RetroRocket
 
Благодарю Вас!

Всего записей: 707 | Зарегистр. 19-02-2008 | Отправлено: 21:33 29-05-2020 | Исправлено: Artem_Butenko, 21:33 29-05-2020
Silver Raven

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Народ, что-то я никак не дойду, до того так вычленить нужный параметр из конфига и заменить переменную, не ломая его структуру. Уже и так и сяк игрался...
 

Код:
 
cls
:: Поиск идентификатора обновления сборки и вывод стартового сообщения
if "%UpdateInstalled%" == "true" (
cls
color f2
 echo.
 echo *ВНИМАНИЕ! Запущен режим обновления сборки. Он предназначен для переименования, перемещения и удаления ненужных или устаревших файлов, плагинов и папок.
 echo.
 echo Пожалуйста, не закрывайте данное окно до окончания его работы и вывода на экран главного меню.
 echo.
 echo.
pause
call :editing_start_external_cmd
)
 
:autoupdate_start_external_cmd
cls
if not exist "Модуль автообновления.cmd" (
color fc
 echo.
 echo *ОШИБКА! Не обнаружен cmd 'Модуль автообновления'.
 echo. Процесс автообновления сборки будет прерван. Переустановите пакет с обновлением.
 echo.
 echo.
pause
exit
)
 
start /wait /b "Панель управления" "Модуль автообновления.cmd"
del /q "Модуль автообновления.cmd"
 
:editing_main_config
:: Чтение конфиг-файла main_config.cfg
<"%MainConfig%" (for /f  "eol=; delims=" %%A in ('more') do @set "%%A"& call :write_main_config "%%A")
>nul move $ "%MainConfig%"
 
cls
color f2
 echo.
 echo  *Операции с файлами успешно завершены.
 echo.
 echo.
 echo Для корректной работы сборки, рекомендуется заново скопировать отсортированный список загрузки модов и файлы настроек игры. Если у вас уже установлены какие-либо дополнительные плагины, потребуется провести их повторную сортировку вручную через программу LOOT.
 echo.
 echo.
pause
exit
 
:: Запись в конфиг-файл main_config.cfg
:write_main_config
 >>$ (<nul set /p="%~1"|>nul find "UpdateInstalled=" && (
   echo %UpdateInstalled%|>nul find "true" && (echo UpdateInstalled=false& echo:)
  ) || (
   echo %~1& echo:
 )
)
exit /b
 

 
Cам конфиг:

Код:
 
UpdateInstalled=true
 
ModsPackVersion=1.4.0 BETA 12
 
UninstallFilesList=dxgi.* d3d11.* d3dcompiler_46e.* d3dx9_42.* enbadaptation.* enbbloom.* enbdepthoffield.* enbeffect.* enbeffectpostpass.* enbeffectprepass.* enblens.* enblocal.* enbpalette.* enbraindrops.* enbseries.* enbsunsprite.* enbunderwater.* enbunderwaternoise.* "Silver Raven ReShade preset.ini" skse64_*.* tbb.* tbbmalloc.* "Licence Silver Raven mods pack.*" "Readme Silver Raven mods pack.*" "Readme updates Silver Raven mods pack.*"
 
UninstallFoldersList=enbcache enbseries reshade-shaders "Silver Raven mods pack data"
 

Всего записей: 149 | Зарегистр. 12-10-2012 | Отправлено: 21:39 29-05-2020 | Исправлено: Silver Raven, 21:42 29-05-2020
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Silver Raven
Сформулируйте лаконичнее. Разбираться в вашем коде, чтобы понять вопрос, желания нет.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 23:01 29-05-2020
Silver Raven

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
Ок, пытаюсь максимально кратко. Это:

Код:
 
set "MainConfig=data\main_config.cfg"
 
if "%UpdateInstalled%" == "true" call :test
 
:test
<"%MainConfig%" (for /f  "eol=; delims=" %%A in ('more') do @set "%%A"& call :write_main_config "%%A")
>nul move $ "%MainConfig%"
 
:: бла-бла-бла
 
:: Запись в конфиг-файл main_config.cfg
:write_main_config
 >>$ (<nul set /p="%~1"|>nul find "UpdateInstalled=" && (
   echo %UpdateInstalled%|>nul find "true" && (echo UpdateInstalled=false& echo:)
  ) || (
   echo %~1& echo:
 )
)
exit /b
 

 
Ломает структуру конфига, показанного в моем комментарии выше.  
В конец каждой строки добавляется:

Код:
|>nul find "UpdateInstalled=UpdateInstalled=false

 
Требуется только замена значения UpdateInstalled=true на false
 
Явно нужно смотреть в сторону "eol=; delims=" Видимо из-за использования кавычек, для экранирования имен файлов и папок с пробелами - проблемы.

Всего записей: 149 | Зарегистр. 12-10-2012 | Отправлено: 23:51 29-05-2020 | Исправлено: Silver Raven, 23:55 29-05-2020
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Silver Raven

Цитата:
Требуется только замена значения UpdateInstalled=true на false


Код:
 
:_TmpFile1
set "_TmpFile1=%Temp%\%random%.txt"
if exist "%_TmpFile1%" goto _TmpFile1
 
for /f usebackq^ delims^=^ eol^= %%A in ("%MainConfig%") do (
  for /f delims^=^=^ tokens^=1*^ eol^= %%B in ("%%A") do (
    >> "%_TmpFile1%" (
      if /i %%B==UpdateInstalled (
        echo %%B=false
      ) else (
        echo %%A
      )
    ) || (
      del "%_TmpFile1%"
      exit /b 1
    )
  )
)
move /y "%_TmpFile1%" "%MainConfig%"
 

Внешний цикл - на тот случай, если прочие значения конфига могут начинаться на "=".

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 01:14 30-05-2020 | Исправлено: GCRaistlin, 13:22 30-05-2020
Silver Raven

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
То, что нужно, благодарствую. А что добавить, чтобы сохранить расстояние между строками конфига?

Всего записей: 149 | Зарегистр. 12-10-2012 | Отправлено: 12:51 30-05-2020
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Silver Raven
Можно прикрутить костыль с findstr (по мотивам http://www.elisanet.fi/tsalmi/info/tscmd064.html), но я бы не рекомендовал, потому что это накладывает новое условие: имя параметра не должно начинаться на ":". Это условие, в свою очередь, можно убрать другим костылем, но оно вам надо? По-моему, проще вместо пустых строк добавлять пустой комментарий (";"). Поправил код для переноса комментариев.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 13:27 30-05-2020
Silver Raven

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Еще такой вопрос. Не происходит переход на autoupdate_editing_main_config в коде:
 

Код:
 
set "ENBDLL=d3d11.dll"
 
:autoupdate_start_external_cmd
cls
if not exist "Модуль автообновления.cmd" (
color fc
 echo.
 echo *ОШИБКА! Не обнаружен cmd 'Модуль автообновления.
 echo. Процесс автообновления сборки будет прерван. Переустановите пакет с обновлением.
 echo.
 echo.
pause
exit
)
 
start /wait /b "Панель управления" "Модуль автообновления.cmd"
del /q "Модуль автообновления.cmd"
 
 
:autoupdate_enb_package
if exist "%ENBDLL%" (
cls
color f2
 echo.
 echo  Обнаружены файлы пакета шейдеров ENB. Выполнить обновление?
 echo  *Если вы сменили пресет NVT ENB, входящий в состав сборки по-умолчанию, на свой вариант - пропустите данную операцию!
 echo.
 echo.
 echo  Нажмите Y для запуска процедуры обновления или N для отмены и пропуска данной операции.
 echo.
 echo.
 
set /p Var="> Введите свой ответ и нажмите Enter: "
if %Var%==y call :autoupdate_enb_package_reinstall
if %Var%==n call :autoupdate_editing_main_config
goto :autoupdate_enb_package
)
 
goto :autoupdate_editing_main_config
 

 
Пояснения: 1. выполняем внешний cmd-шник, ждем его окончания. 2. Проверяем наличие d3d11.dll и соответствующий код при его обнаружении, либо пропускаем и переходим к autoupdate_editing_main_config. Вот только этого не происходит. Почему?

Всего записей: 149 | Зарегистр. 12-10-2012 | Отправлено: 14:25 30-05-2020 | Исправлено: Silver Raven, 14:38 30-05-2020
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Silver Raven
Потому что %Var% разворачивается в момент чтения блока, а не при выполнении команды. Включите delayed expansion и обращайтесь к !Var!. Это вообще всегда строго рекомендуется, когда имеешь дело с непредсказуемым вводом.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 15:26 30-05-2020
Silver Raven

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
Никогда бы до такого не додумался. Спасибо.
 
Будет ли правильно работать следующая конструкция?
Родительская папка - Mods pack data (являющейся подпакой для Data), месторасположение обоих (имеется ввиду диск) не будет заранее известно.
 

Код:
 
@echo off
 
:: Быстрое возвращение в родительскую папку
setlocal enabledelayedexpansion
set HomeFolder=%CHDIR%
chdir ..
 
:: Операции с файлами и папками сборки
del /q autoupdate.cfg fileslist.cfg uninstall.cfg
 
chdir Mods pack data\Additional options
ren "ESP russian localization pack" "Russian localization sounds package"
 
chdir Mods pack data\ENB
del /q enbadaptation.* enbbloom.* enbdepthoffield.* enbeffect.* enbeffectpostpass.* enbeffectprepass.* enblens.* enbpalette.* enbraindrops.* enbsunsprite.* enbunderwater.* enbunderwaternoise.*
 
chdir Mods pack data\ENB\enbseries
del /q enbsunsprite.bmp
chdir !HomeFolder:%CHDIR%\=!
 
:: В теории, здесь мы попадаем в Data. Файлы внутри нее.
cd ..
del /q enbadaptation.* enbbloom.* enbdepthoffield.* enbeffect.* enbeffectpostpass.* enbeffectprepass.* enblens.* enbpalette.* enbraindrops.* enbsunsprite.* enbunderwater.* enbunderwaternoise.*
 
cd Data\SKSE\Plugins\StorageUtilData\PCHeadTracking
del /q silver_raven_settings.*
 
cd Data\Textures\actors\character\argonianfemale
del /q argonianfemalebody2.*
 
cd Data\Textures\actors\character\khajiitmale
del /q bodymale.psd
 
timeout /t 2
endlocal
exit
 

 
Или надежнее как-то узнать полные пути для папок. Запихать их в переменные HomeFolder1 и HomeFolder2, и подставлять по необходимости?

Всего записей: 149 | Зарегистр. 12-10-2012 | Отправлено: 12:22 31-05-2020 | Исправлено: Silver Raven, 12:25 31-05-2020
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Silver Raven

Цитата:
Будет ли правильно работать следующая конструкция?

В общем случае - нет. Во-первых, нужно всегда проверять результат выполнения команды:

Код:
 
cd <dir> || exit /b
 

И не только CD, но и REN, COPY и прочих. DEL это не касается, т. к. она всегда возвращает 0.
Во-вторых, так:

Код:
 
!HomeFolder:%CHDIR%\=!
 

делать не стоит, т. к. %CHDIR% может содержать "!". Правда, я вообще не понял цели этой замены.
 
Это общие замечания. С алгоритмом не разбирался. Кстати, для быстрого возврата в исходный каталог лучше использовать пару PUSHD/POPD (опять же с проверкой результата).

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 14:22 31-05-2020
vaskamy



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Нашол два древних батника для конвертирования Registry.rw.tvr в reg файл реестра.
Батники как дополнение к программе VMware ThinApp.
Подскажите пожалуйста как пользоваться батниками - что где должно быть и откуда запускать?
Или может их нужно подправить или переписать.
Кто разбирается помогите.
 
 
@echo off  
set PROJECT_DIR=%CD%  
set THINSTALL_BIN=%PROJECT_DIR%  
"%THINSTALL_BIN%\vregtool.exe" "%THINSTALL_BIN%\Registry.rw.tvr" ExportReg "%THINSTALL_BIN%\filename.reg"
 
 
 
 
@echo off
if "%~1"=="" (
    echo Usage: %~nx0 "*.rw.tvr"
    goto :EOF
)
set "inFile=%~1"
if not exist %inFile% (
    echo File %inFile% not exist!
    goto :EOF
)
set "THINSTALL_BIN=%~dp0..\.."
set "outFile=%~dpn1.reg"
"%THINSTALL_BIN%\vregtool.exe" "%inFile%" ExportReg "%outFile%"
pause
 

Всего записей: 966 | Зарегистр. 04-03-2017 | Отправлено: 15:46 31-05-2020 | Исправлено: vaskamy, 12:05 01-06-2020
Silver Raven

Junior Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
GCRaistlin
Ок. А pushd cd .. для Data\Mods pack data сработает? Тут неудобство в том, что получается у меня два основных каталога между которыми нужно иметь возможность быстро переключаться, добавляя к пути только подпапки.
 

Код:
 
@echo off
 
:: Запоминаем родительскую папку Data
pushd cd ..
 
:: Операции с файлами и папками сборки
del /q enbadaptation.* enbbloom.* enbdepthoffield.* enbeffect.* enbeffectpostpass.* enbeffectprepass.* enblens.* enbpalette.* enbraindrops.* enbsunsprite.* enbunderwater.* enbunderwaternoise.*
 
popd SKSE\Plugins\StorageUtilData\PCHeadTracking
del /q silver_raven_settings.*
 
popd Textures\actors\character\argonianfemale
del /q argonianfemalebody2.*
 
popd Textures\actors\character\khajiitmale
del /q bodymale.psd
 
popd Mods pack data
del /q autoupdate.cfg fileslist.cfg uninstall.cfg
 
popd Mods pack data\Additional options
ren "ESP russian localization pack" "Russian localization sounds package" || exit /b
 
popd Mods pack data\ENB
del /q enbadaptation.* enbbloom.* enbdepthoffield.* enbeffect.* enbeffectpostpass.* enbeffectprepass.* enblens.* enbpalette.* enbraindrops.* enbsunsprite.* enbunderwater.* enbunderwaternoise.*
 
popd Mods pack data\ENB\enbseries
del /q enbsunsprite.bmp
 
timeout /t 2
exit
 

Всего записей: 149 | Зарегистр. 12-10-2012 | Отправлено: 17:16 31-05-2020
GCRaistlin



Silver Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Silver Raven
Вы код не тестируете, что ли, пытаетесь заранее угадать, будет работать или нет? Почитайте справку по PUSHD, у вас сейчас написаны глупости. Кроме того, нужно писать, что вы хотите получить, и чем подробнее, тем лучше. Разбираться в чужом коде, повторяю, желания нет. И кстати, рекомендую в первую очередь для себя взять за правило вставлять комментарии. Сэкономите кучу времени и усилий, когда чуть позже будете пытаться понять, что и зачем вы понаписали.

----------
Magically yours
Raistlin

Всего записей: 3962 | Зарегистр. 18-04-2005 | Отправлено: 18:52 31-05-2020
vaskamy



Advanced Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Помогите сделать чтобы при повторном запуске - текст файл не заменялся а рядом создавался
новый в имени файла с цифрой или секундами.
 
chcp 1251
echo %date% %time% >filelist.txt
dir /b /d >>filelist.txt

Всего записей: 966 | Зарегистр. 04-03-2017 | Отправлено: 12:23 03-06-2020
   

Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии (bat, cmd)
Maz (19-09-2020 13:36): Командная строка, батники, сценарии (bat, cmd) Часть 6


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru