Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd

Модерирует : gyra, Maz

 Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

Открыть новую тему     Написать ответ в эту тему

KiloSub



Full Member
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Код:
 
@echo off
chcp 65001 >nul
pushd "%~dp0"
color f0
setlocal enabledelayedexpansion
 
for /f "tokens=1 delims=:" %%A in ('findstr /xnc:"<Clusters>" "%~f0"') do set Skip=%%A
 
for /f "tokens=1-5" %%A in ('"echo list disk | diskpart | findstr /irc:"Disk [0-9]""') do (
    echo %%A %%B - %%D %%E
    call :Line
    for /f "tokens=2" %%P in ('"(echo select disk %%B & echo list partition) | diskpart | findstr /irc:"Partition [0-9]""') do (
        call :Cluster %%B %%P
    )
    echo.
)
call :Line
pause
exit
 
:Cluster
set Flag=type
for /f "tokens=2 delims=:" %%S in ('"(echo select disk %1 & echo select partition %2 & echo filesystems) | diskpart | findstr /i "Type Unit""') do (
    if "!Flag!"=="type" (
        set Flag=cluster
        set "V=     %%S"
        set "V=!V:~-6!"
        <nul set /p "Tmp=%%P ^>^> !V! : "
    ) else (
        call :ClusterView %%S
        exit /b
    )
)
exit /b
 
:ClusterView
for /f "usebackq skip=%Skip% tokens=1-2 delims==" %%K in ("%~f0") do (
    if "%%K"=="</Clusters>" exit /b
    if /i %1==%%K (
        echo %%L
        exit /b
    )
)
exit /b
 
:Line
echo -------------------------------
exit /b
 
<Clusters>
4096=4096
8192=8192
16384=16K
16K=16K
32768=32K
32K=32K
65536=64K
64K=64K
</Clusters>
 

Всего записей: 420 | Зарегистр. 30-05-2020 | Отправлено: 16:17 11-04-2021
Открыть новую тему     Написать ответ в эту тему

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru