Перейти из форума на сайт.

НовостиФайловые архивы
ПоискАктивные темыТоп лист
ПравилаКто в on-line?
Вход Забыли пароль? Первый раз на этом сайте? Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd

Модерирует : gyra, Maz

 Версия для печати • ПодписатьсяДобавить в закладки
На первую страницук этому сообщениюк последнему сообщению

Открыть новую тему     Написать ответ в эту тему

KiloSub



Запрет на пост
Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Код:
 
@echo off
 
for /f "delims=:" %%A in ('findstr /xnc:"<Services>" "%~f0"') do set "Skip=%%A"
 
set Mode=0
call :ServicesHandler
 
echo 1 - Stop Services
echo 2 - Start Services
echo.
 
:Input
set /p "Mode=Mode: "
for %%M in (1,2) do if %Mode%==%%M goto :Start
goto :Input
 
:Start
echo.
call :ServicesHandler
echo Done!
pause
exit /b
 
:ServicesHandler
for /f "usebackq skip=%Skip% tokens=1,2" %%A in ("%~f0") do (
    if "%%A"=="</Services>" echo. & exit /b
    echo %%A
    if %Mode%==1 (
        sc config %%A start= disabled
        net stop %%A
    )
    if %Mode%==2 (
        sc config %%A start= %%B
        net start %%A
    )
)
exit /b
 
<Services>
LanmanWorkstation auto
LanmanServer auto
RemoteAccess demand
RemoteRegistry demand
</Services>
 

Всего записей: 386 | Зарегистр. 30-05-2020 | Отправлено: 12:54 09-11-2020 | Исправлено: KiloSub, 14:48 09-11-2020
Открыть новую тему     Написать ответ в эту тему

На первую страницук этому сообщениюк последнему сообщению

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.Board
© Ru.Board 2000-2020

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru