igor_andreev
Advanced Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Вот кусок установки размера окна Far, размера шрифта. Еще под Win 2000 делал, без использования REG.EXE
Код:
REM Выясняем текущий путь Far.exe
SET "CURRENT_FAR_EXE=%~dp0Far.exe"
REM Выясняем текущую рабочую папку Far
SET "CURRENT_FAR_DIR=%~dp0"
REM Удаляем последний обратный слеш в пути к текущей рабочей папке, не нужен он
SET "CURRENT_FAR_DIR=%CURRENT_FAR_DIR:~0,-1%"
REM Удваиваем в пути к экзешнику Far.exe обратные слеши
REM для записи в файл реестра "%TEMP%\FarInAppPaths.reg"
SET "CURRENT_FAR_EXE_DOUBLESLASHED=%CURRENT_FAR_EXE:\=\\%"
REM Удваиваем в пути к рабочей папке слеши, для записи в файл реестра "%TEMP%\FarInAppPaths.reg"
SET "CURRENT_FAR_DIR_DOUBLESLASHED=%CURRENT_FAR_DIR:\=\\%"
REM Записываем путь и раб. папку Far в "%TEMP%\FarInAppPaths.reg"
(
ECHO.REGEDIT4
ECHO.
ECHO.[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Far.exe]
ECHO.@="%CURRENT_FAR_EXE_DOUBLESLASHED%"
ECHO."Path"^="%CURRENT_FAR_DIR_DOUBLESLASHED%"
)>"%TEMP%\FarInAppPaths.reg"
REM Меняем в пути к экзешнику Far.exe обратные слеши на знак подчеркивания
REM для записи в файл реестра "%TEMP%\FarConsoleWindow.reg"
SET "CURRENT_FAR_EXE_UNDERLINED=%CURRENT_FAR_EXE:\=_%"
REM Записываем путь к экзешнику Far.exe в "%TEMP%\FarConsoleWindow.reg"
REM дабы Far запустился с нужными настройками окна
REM Тут свои dword: надо написать из HKCU\Console, это какой-то из моих
REM вариантов не помню для чего даже, кажется для 1024х768
REM Насчет WindowPosition - на PortableFar у мну стоял CenterFarWindow плагин
(
ECHO REGEDIT4
ECHO.
ECHO [HKEY_CURRENT_USER\Console\%CURRENT_FAR_EXE_UNDERLINED%]
ECHO "ScreenBufferSize"=dword:00280064
ECHO "WindowSize"=dword:00220064
ECHO "WindowPosition"=dword:0x00B000B0
ECHO "FontSize"=dword:000e0008
ECHO "FontFamily"=dword:00000036
ECHO "FontWeight"=dword:00000190
ECHO "FaceName"="Lucida Console"
ECHO "HistoryNoDup"=dword:00000000
ECHO "CursorSize"=dword:0000000a
)>"%TEMP%\FarConsoleWindow.reg"
REM Тут еще FarSettings1.reg и FarSettings2 импортировал ...
REM Импортируем свои настройки в реестр
IF EXIST "%TEMP%\FarInAppPaths.reg" START /WAIT REGEDIT /S "%TEMP%\FarInAppPaths.reg"
IF EXIST "%TEMP%\FarConsoleWindow.reg" START /WAIT REGEDIT /S "%TEMP%\FarConsoleWindow.reg"
REM Чтобы настройки HKCU применились в сей же час...
RUNDLL32.EXE user32.dll,UpdatePerUserSystemParameters
REM Удаляем
IF EXIST "%TEMP%\FarInAppPaths.reg" DEL "%TEMP%\FarInAppPaths.reg"
IF EXIST "%TEMP%\FarConsoleWindow.reg" DEL "%TEMP%\FarConsoleWindow.reg"
REM и можно запускать %~dp0Far.exe ...
|
Colorer вот так устанавливал(батник в папке рядом с Far.exe):
Код:
FOR /F "TOKENS=*" %%A IN (
'DIR /S /B *.exe ^| FIND /I "Colorer" ^| FIND /I "install.exe"'
) DO IF NOT "%%A."=="." (
"%%A"
"%%A" -l
COPY /Y "%%~dpA\colorer.ini" "%%~dpA\colorer.ini.def"
"%%A" -i >"%%~dpA\colorer.ini"
)
|
FIND /I "Colorer" - это потому что папка с колорер у меня всегда называлась или Colorer или Colorer4ever или похоже. Да и у всех наверно так называется 
BgCopy в разных вариациях у меня по разному был, и сторонние утилиты использовал чтоб проверить наличие на компе сервиса, и экспортировал
Код:
REGEDIT /EA "%TEMP%\IsInstalledBgCopy.reg" HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\FARBCopy |
а потом проверял наличие файла "%TEMP%\IsInstalledBgCopy.reg"
Но устанавливал обычно так
Код:
FOR /F "TOKENS=*" %%A IN ('DIR /S /B *.exe^|FIND /I "bcsvc.exe"') DO IF NOT "%%A."=="." "%%A" /I
|
и удалял в конце так же, только не /I, а /R. И остальные настройки по завершении Far.exe тоже сносил
Код:
(
ECHO REGEDIT4
ECHO [-HKEY_CURRENT_USER\Software\Far]
ECHO [-HKEY_LOCAL_MACHINE\Software\Far]
ECHO [-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Far.exe]
ECHO [-HKEY_CURRENT_USER\Console\%CURRENT_FAR_EXE_UNDERLINED%]
ECHO [-HKEY_CURRENT_USER\Software\colorer]
)>"%TEMP%\DeleteFarSettings.reg"
IF EXIST "%TEMP%\DeleteFarSettings.reg" START /WAIT REGEDIT /S "%TEMP%\DeleteFarSettings.reg"
|
Еще при запуске Far cmdow.exe скрывал батник и из Фара можно было выходить и по F10 и просто щелкнув по крестику, батник опять появлялся на экране и подчищал все за собой. Был даже какой-то вариант с созданием ярлыка для восстановления настроек на рабочем столе, если флешку резко выдернули и батник не успел отработать. В общем все это было давно уже, 2,5 - 1,5 года назад, батник менялся постоянно, то под разные ОС, то под разные утилиты, а потом я к нему охладел. Имхо правильнее будет, если Far Group сами сделают экзешник PortableFarLauncher.exe для нуждающихся. Корректно работающий WinRAR Unplugged сделали же, значит и Far Unplugged можно.
|
