KiloSub
Full Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Код: @echo off
chcp 866 >nul
pushd "%~dp0"
setlocal enabledelayedexpansion
mode con:cols=200 lines=25
call :Line
for /f "tokens=1 delims=:" %%A in ('findstr /xnc:"[SOURCE]" "%~f0"') do set "Skip=%%A"
set Count=0
for /f "usebackq skip=%Skip% tokens=*" %%A in ("%~f0") do (
set /a Count+=1
set "Count= !Count!"
set "Count=!Count:~-3!"
echo !Count! : %%A
)
call :Line
call :Input
echo.
set "out=%~dp0"
set ISO=noname
call :Line
set Count=0
pushd "%Source%"
for /f "tokens=*" %%F in ('dir /s /b *.iso 2^>nul') do (
set /a Count+=1
set "Count= !Count!"
set "Count=!Count:~-3!"
echo !Count! : %%~nF
)
if %Count%==0 echo ISO not found & echo. & pause & exit
call :Line
call :Seacher
echo.
call :Line
if "%ISO%"=="noname" echo ISO not found & pause & exit
for %%N in (%ISO%) do set "name=%%~nN"
echo Копирование из ^>^> %name% ...
PowerShell.exe -NoProfile -Command "Copy -Force ((Mount-DiskImage '%ISO%' | Get-Volume).DriveLetter + ':\sources\install.wim') '%out%'; [void] (Dismount-DiskImage '%ISO%')"
attrib -r "%out%\install.wim"
call :Line
pause
exit /b
:Input
set /p "Number=Выберите расположение: "
set /a Count=0
for /f "usebackq skip=%Skip% tokens=*" %%A in ("%~f0") do (
set /a count+=1
if "-!count!"=="-%Number%" (
set "Source=%%A"
exit /b
)
)
goto :Input
:Seacher
set /p "Number=Выберите образ: "
set /a Count=0
for /f "tokens=*" %%F in ('dir /s /b *.iso') do (
set /a count+=1
if "-!count!"=="-%Number%" (
set "ISO=%%F"
exit /b
)
)
goto :Seacher
:Line
echo --------------------------------------------------------------------------------
exit /b
[SOURCE]
d:\ISO\
d:\Downloads\
|
|
Всего записей: 420 | Зарегистр. 30-05-2020 | Отправлено: 00:15 29-11-2020 | Исправлено: KiloSub, 03:10 30-11-2020 |
|
