Перейти из форума на сайт.

Новости • Файловые архивы
Поиск • Активные темы • Топ лист
Правила • Кто в on-line?
Вход • Забыли пароль? • Первый раз на этом сайте? • Регистрация
Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd

Модерирует : gyra, Maz

 Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192

Открыть новую тему     Написать ответ в эту тему

Maz



Дед Мазай		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Командная строка, батники\сценарии (bat, cmd)
часть 1 | часть 2 | часть 3 | часть 4 | часть 5
Вопросы, задачи и их решения по работе с командной строкой, файлами, а также сопутствующие ссылки.

Важно: копируя батник через буфер обмена из форума не забывайте удалять пробелы в конце каждой строки, т.к. в некоторых случаях из-за этого программа будет работать неправильно!!! Чтобы не копировались концевые пробелы из форума, жмите на ссылку "Редактировать" в посте, и уже из редактора копируйте батник без пробелов.
 
Примечание: Большие куски кода заключайте в тэг [ more ].  
Смежные темы:
В помощь системному администратору > Автоматизация администрирования
Microsoft Windows > Сценарии Windows
Полезные ссылки:
· Из Windows XP Professional Product Documentation:
> Описание Cmd.exe > Command shell overview
> Using batch files > Using batch parameters > Using filters > Using command redirection operators
 
· Уроки bat-аники (для начинающих): первый и второй
· Курс из 19 лекций "Командная строка и сценарии Windows"
· Уильям Р. Станек - Командная строка Windows. Справочник администратора
 
· Выполнение BAT-скриптов без вызова окна консоли
· cmdow - изменение параметров и видимости дос-окна, Статья в КОМПЬЮТЕРРАONLINE
· Набор GNU утилит для win32
· HS_Packet.7z - Пакет утилит для организации интерфейса в bat-файлах
· blat - отправка почты из консоли
· Easy Batch Builder+Rus+Crack - Редактор BAT файлов.Через графический интерфейс программы вы сможете быстро конструировать пакетные файлы практически любой сложности. (В комплекте есть Лоадер созданный с помощью Sign Of Misery некоторые антивирусы обзывают его вирусом. Вам решать: ставить или не ставить) (ЗЕРКАЛО)
· Простой способ получать текущую дату всегда в одном формате (не зависит от языков и настроек) ещё и ещё
· Переход из 32-битной версии cmd.exe в 64-битную (1) (2)(3)
 
· Архив всевозможных версий cmd.exe (от Windows NT 3.10 до Windows 11 +Win95cmd +ReactOS) и command.com (DOS 5.0 и выше). Старые командные процессоры можно запускать на более новых ОС, хотя не всё может работать корректно. Подробная документация по командам cmd.exe и стандартным утилитам ОС для NT 3.51, NT 5.0 (Windows 2000) и NT 5.2 (Windows Server 2003). Сборник представляет исторический интерес, а также незаменим для тех, у кого появилось желание сделать свои скрипты работоспобными не только на своей версии ОС.
 
· Большой сборник одним архивом: Сотни Win32 утилит командной строки, нетривиальные .cmd файлы, .bat miniperl скрипты (не требующие полноценной установки Perl), FAR Manager с плагинами и настройками, разное для DOS/DOSBox (откуда под Win32 интерес представляют три продвинутых "мультисистемных" .bat файла да ещё, может быть, оболочка Necromancer DOS Navigator с поддержкой LFN и доступом к буферу обмена Windows). Краткие описания всего - в файликах files.bbs
Всего записей: 38836 | Зарегистр. 26-02-2002 | Отправлено: 13:35 19-09-2020 | Исправлено: metatrop, 07:55 29-11-2022
351878



Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
подскажите можно ли как-то сделать чтоб в вводимых значениях переменной автоматом подставлялись знаки двоеточия и точки по шаблону? и чтоб после трёхзначного числа после точки жался enter.
00:00:00.000  
 

Код:
SetLocal EnableDelayedExpansion
set /p From="Start: "
set /p To="End: "
ffmpeg -i %%x -ss !From! -to !To! -c: copy "%%~nx%%~xx"
Всего записей: 999 | Зарегистр. 28-03-2016 | Отправлено: 09:28 01-06-2023 | Исправлено: 351878, 09:37 01-06-2023
Simple Code

Junior Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
351878
Upd:
Вот по пробуйте такой вариант. Правда не уверен то, не то, но если что сами скорректируете как надо.
Всего записей: 172 | Зарегистр. 19-11-2022 | Отправлено: 02:53 02-06-2023 | Исправлено: Simple Code, 15:26 02-06-2023
351878



Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Simple Code
супер, мега спасибище. отлично работает.
но мне не удаётся его вписать в батник с драг энд дропом. со скобками где то косяк?
делал так:
Всего записей: 999 | Зарегистр. 28-03-2016 | Отправлено: 13:46 02-06-2023
pressF



Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Есть вот такой батник мем
https://paste.gg/p/anonymous/b7a87c9c4b5c4228903c2861ff534fa5/files/2da9918ce6f145bd96fef3a41e2b9f6a/raw
Помогите его переделать к нормальному виду, чтобы можно было перечислять как в json, по адресу на строку, дабы в последствии это всё было мега удобно редактировать (добавлять/удалять). И с проверкой на адреса аналогично.
 
[
adobe.com.tw
123.adobe.reg.com
]
Всего записей: 1121 | Зарегистр. 29-03-2023 | Отправлено: 19:52 10-06-2023
Pasha_ZZZ



Platinum Member		Редактировать | Профиль | Сообщение | ICQ | Цитировать | Сообщить модератору
pressF

Код:
 
@echo off
title Блокировка адресов, ответственных за проверку лицензий Adobe CC
 
echo Блокировка в файле hosts адресов, ответственных за проверку
echo легитимности лицензий продуктов семейства Adobe CC
echo _______________________________________________________________________
echo.
 
set "hosts=%WINDIR%\system32\drivers\etc\hosts"
>nul ren "%hosts%" hosts77 || call :PauseExit "Файл hosts заблокирован для редактирования." "" "Либо Вы запустили данный патч не от имени администратора," "либо внесение изменений блокирует установленный у Вас антивирус."
ren "%hosts%77" hosts >nul
for /f "tokens=1*" %%a in ('findstr /i /b /l /c:"::host" "%~f0"') do call :AddHost "%%b"
echo.
ipconfig /flushdns >nul
echo Кэш сопоставителя DNS успешно очищен.
echo _______________________________________________________________________
echo.
echo Все необходимые изменения успешно внесены!
echo.
pause
goto :eof
 
:PauseExit
if #%1#==## goto :ToPause
if %1=="" (echo.) else echo %~1
shift
goto :PauseExit
:ToPause
pause
exit
 
:AddHost
>nul findstr /i /l /c:" %~1" "%hosts%" && goto :DontAdd
echo 127.0.0.1 %~1 >> "%hosts%"
echo Адрес %1 успешно добавлен в файл hosts.
goto :eof
:DontAdd
echo Адрес %1 уже имеется в файле hosts.
goto :eof
 
 
 
::host na1r.services.adobe.com
::host hlrcv.stage.adobe.com
::host lmlicenses.wip4.adobe.com
::host lm.licenses.adobe.com
::host activate.adobe.com
::host practivate.adobe.com
 

В cmd-файле где угодно (у меня в конце) добавляете строку, начинающуюся с ::host и потом указываете нужный адрес.
Всего записей: 12402 | Зарегистр. 11-03-2002 | Отправлено: 07:45 11-06-2023 | Исправлено: Pasha_ZZZ, 07:47 11-06-2023
pressF



Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Pasha_ZZZ
Очень достойно вышло
Поделюсь им в соседней теме
Всего записей: 1121 | Зарегистр. 29-03-2023 | Отправлено: 17:02 11-06-2023
sakatgg

Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
В XviD4PSP 8 использую редактор глав, он понимает такой формат глав в файле *.txt, пример:
 

Код:
00:00:00.000 Привет, друзья
00:00:37.000 Контрнаступление в тумане
00:01:38.000 Удар на Запорожском направлении
00:04:00.000 Украина теряет «Леопарды» и просит Patriot
00:08:18.000 Катастрофа Каховской ГЭС
00:11:30.000 Версии обрушения плотины
00:13:13.000 Долгосрочные последствия экоцида
00:15:04.000 Ситуация в Новой Таволжанке
00:16:50.000 «Вагнер» взял в плен подполковника Веневитина
00:18:32.000 Взрыв аммиакопровода Тольятти-Одесса

 
 
Но с ютуба список есть только в таком виде
 

Код:
0:00 Привет, друзья
0:37 Контрнаступление в тумане
1:38 Удар на Запорожском направлении
4:00 Украина теряет «Леопарды» и просит Patriot
8:18 Катастрофа Каховской ГЭС
11:30 Версии обрушения плотины
13:13 Долгосрочные последствия экоцида
15:04 Ситуация в Новой Таволжанке
16:50 «Вагнер» взял в плен подполковника Веневитина
18:32 Взрыв аммиакопровода Тольятти-Одесса

 
Подскажите батник, чтобы дописывал "0" ":" "." по форме, нужной для XviD4PSP 8.
Приходиться каждый раз ручками редактировать длинные списки. Спасибо.
Всего записей: 1119 | Зарегистр. 18-11-2006 | Отправлено: 17:14 11-06-2023 | Исправлено: sakatgg, 17:17 11-06-2023
BorlandIMHO

Silver Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
sakatgg

Цитата:
батник, чтобы дописывал "0" ":" "."


Код:
@echo off
setlocal ENABLEDELAYEDEXPANSION
if /I "%~1*" == "*" exit
for /F "usebackq tokens=1,* delims= " %%A in (`type "%~1"`) do (
    call :CONVERTTIME %%A NEWTIME
    1>>"%~n1_xv%~x1" echo !NEWTIME! %%B
)
goto :EOF
 
:CONVERTTIME
for /F "tokens=1,2 delims=:" %%T in ("%1") do (
    set MINUTES=0%%T
    set MINUTES=!MINUTES:~-2!
    set SECONDS=0%%U
    set SECONDS=!SECONDS:~-2!
    set "%~2=00:!MINUTES!:!SECONDS!.000"
)
goto :EOF

запускать "батник.cmd конвертируемыйфайл.txt"
на выходе "конвертируемыйфайл_xv.txt"

----------
http://www.imho.ws
Всего записей: 2403 | Зарегистр. 12-10-2006 | Отправлено: 19:42 11-06-2023 | Исправлено: BorlandIMHO, 20:49 11-06-2023
sakatgg

Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
BorlandIMHO, спасибо большое, четко работает  
 
Еще сопутствующий вопрос, почему получается вот такая обрезка (одно слово после тайм кода)?  
Такая же обрезка происходит когда открываю *.txt в XviD4PSP 8 и приходится доставлять названия глав.
Я предполагал это глюк XviD4PSP 8. Но после Вашего батника также обрезается и подумал, может дело в другом?
Может важен формат *.txt (создаю в Synwrite в UTF-8, без BOM, Win, text files)?
 

Код:
00:00:00.000 Привет,
00:00:37.000 Контрнаступление
00:01:38.000 Удар
00:04:00.000 Украина
00:08:18.000 Катастрофа
00:11:30.000 Версии
00:13:13.000 Долгосрочные
00:15:04.000 Ситуация
00:16:50.000 «Вагнер»
00:18:32.000 Взрыв

 
P.S.

Цитата:
В четвёртой строчке должно быть не "2*", а просто "*".
Поправил.

Ок, теперь нормально, не обрезает после батника.  
 
P.S.2
Simple Code

Цитата:
Как альтернатива (Drag and Drop):

Ок, супер, спасибо.  
Всего записей: 1119 | Зарегистр. 18-11-2006 | Отправлено: 20:27 11-06-2023 | Исправлено: sakatgg, 22:23 11-06-2023
BorlandIMHO

Silver Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
sakatgg
Моя ошибка
В четвёртой строчке должно быть не "2*", а просто "*".
Поправил.

----------
http://www.imho.ws
Всего записей: 2403 | Зарегистр. 12-10-2006 | Отправлено: 20:49 11-06-2023
Simple Code

Junior Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору

Цитата:
Подскажите батник, чтобы дописывал "0" ":" "." по форме, нужной для XviD4PSP 8.

Как альтернатива (Drag and Drop):

Код:
 
@echo off
SetLocal EnableDelayedExpansion
for /f "Tokens=1,2,* Delims=: " %%i in ('type %1') do (
    set m=0%%~i
    echo 00:!m:~-2!:%%~j.000 %%~k>>"%~np1_Parse.txt"
)
 
Всего записей: 172 | Зарегистр. 19-11-2022 | Отправлено: 21:48 11-06-2023 | Исправлено: Simple Code, 22:06 11-06-2023
BorlandIMHO

Silver Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Simple Code

Цитата:
Drag and Drop

Ну, если по честному - мой батник тоже может D-n-D с одиночным текстовиком.
Как, собственно, и любой другой батник, принимающий параметром имя файла для обработки.
Просто если уж заводить речь о D-n-D, то неплохо бы и обработку пачки организовать...
Всего записей: 2403 | Зарегистр. 12-10-2006 | Отправлено: 00:32 12-06-2023
Simple Code

Junior Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
BorlandIMHO
Подробнее...
 
Multi Drag-and-Drop

Код:
 
@echo off
SetLocal EnableDelayedExpansion
for %%f in (%*) do (
    for /f "Tokens=1,2,* Delims=: " %%i in ('type %%f') do (
        set m=0%%~i
        echo 00:!m:~-2!:%%~j.000 %%~k>>"%%~dpnf_Parse.txt"
    )
)
 
Всего записей: 172 | Зарегистр. 19-11-2022 | Отправлено: 01:25 12-06-2023 | Исправлено: Simple Code, 18:09 12-06-2023
Egor2020

BANNED		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Как с помощью консольного ZIP-архиватора pkzipc.exe (входит в состав сборника утилит командной строки http://f.rodon.org/m2/win32-and-dos-exefiles.7z) распаковать ZIP-архив с сохранением структуры папок, а не по принципу "все файлы в одну кучу"? Хочу включить в BAT-вирус универсальную утилиту командной строки TCIMG с полным комплектом необходимых для ее работы файлов и скомпилировать BAT-вирус со вшитой утилитой TCIMG с помощью Bat To Exe Converter.
Всего записей: 1726 | Зарегистр. 01-03-2020 | Отправлено: 18:47 12-06-2023 | Исправлено: Egor2020, 18:55 12-06-2023
Mr_Hat



Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Egor2020
pkzipc.exe -extract -dir <путь к архиву> <путь для распаковки>
Всего записей: 984 | Зарегистр. 04-10-2005 | Отправлено: 19:16 12-06-2023
ziabriev



Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Egor2020
С помощью wget.exe и UnZip.exe (из папки %COMMANDER_PATH%\Plugins\exe\Plugman\UnZip.exe)
Install.bat:

Код:
@Echo off
Color 02
Title Скрипт обновления TCIMG
echo Запуск
>nul 2>&1 taskkill /IM TCIMG.exe /F
>nul 2>&1 timeout /t 5
echo Загрузка
>nul 2>&1 wget.exe -O TCIMG.zip --tries=10 http://wincmd.ru/download.php?id=TCIMG  
>nul 2>&1 unzip -o TCIMG -d%COMMANDER_PATH%\
echo Завершение
>nul 2>&1 timeout /t 5
%COMMANDER_PATH%\TCIMG.exe rstart pause=800 infbx=InfoBox13
 

Пути свои.
Всего записей: 1308 | Зарегистр. 03-03-2019 | Отправлено: 19:33 12-06-2023
Egor2020

BANNED		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Как в BAT-файле сгенерировать случайным образом одно или несколько состоящих из латинских букв и цифр имен временных файлов и/или папок, которые необходимо создать в папке %Temp%, и записать эти имена в переменные? Чтобы гарантировалось отсутствие в папке %Temp% одноименных файлов и/или папок.
Всего записей: 1726 | Зарегистр. 01-03-2020 | Отправлено: 12:37 13-06-2023 | Исправлено: Egor2020, 12:42 13-06-2023
GCRaistlin



Silver Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Egor2020

Код:
 
:_TmpFile0
set "_TmpFile0=%Temp%\%~n0%random%.txt"
if exist "%_TmpFile0%" goto _TmpFile0
 


----------
Magically yours
Raistlin
Всего записей: 4000 | Зарегистр. 18-04-2005 | Отправлено: 13:00 13-06-2023
BorlandIMHO

Silver Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Egor2020
Случайное число генерируется {и записывается в переменную} так: https://ss64.com/nt/syntax-random.html
Если чисто числа недостаточно - придётся "городить огород" и генерировать имя в цикле по одному символу.
Гарантировать отсутствие - только проверкой по if EXIST и повторная генерация при наличии.

----------
http://www.imho.ws
Всего записей: 2403 | Зарегистр. 12-10-2006 | Отправлено: 13:06 13-06-2023
ewild

Advanced Member		Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Egor2020
 

Код:
set "var=foo"
call :ndate
 
set "var=bar"
call :ndate
 
set "var=var"
call :ndate
 
goto :eof
 
:ndate
for /f "delims=" %%d in ('powershell get-date -format "{yyyyMMdd_HHmmssfffff}"') do set d=%%d
echo %var%>%temp%\var_%d%.txt
exit /b

 
Для подобной задачи пвсевдослучайность (и тем самым, неповторимость) имени вполне гарантируется текущей датой/временем (в примере - с точностью до стотысячных долей секунды (fffff)).
При необходимости, дисло этих долей (число f) можно переподобрать по вкусу.  
Всего записей: 1196 | Зарегистр. 13-08-2005 | Отправлено: 16:59 13-06-2023
Открыть новую тему     Написать ответ в эту тему

Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192

Компьютерный форум Ru.Board » Компьютеры » Программы » Командная строка, батники, сценарии - bat, cmd


Реклама на форуме Ru.Board.

Powered by Ikonboard "v2.1.7b" © 2000 Ikonboard.com
Modified by Ru.B0ard
© Ru.B0ard 2000-2024

BitCoin: 1NGG1chHtUvrtEqjeerQCKDMUi6S6CG4iC

Рейтинг.ru